#include <Mouse.h>
#include <Keyboard.h>
#include <stdlib.h>

// hardware
int KEYBOARD_DELAY = 20;
int MOUSE_DELAY = 20;
const int SERIAL_PORT = 9600;
const int SERIAL_DELAY = 100;
#define MAX_BUFFER_SIZE 64
#define led 13

// protocol
#define SET_DELAY '0'
#define SET_KEYBOARD_DELAY '0'
#define SET_MOUSE_DELAY '1'
#define PRESS_KEY '1'
#define PRINT_STRING '2'
#define KEY_DOWN '3'
#define KEY_UP '4'
#define MOUSE_MOVE '5'
#define MOUSE_CLICK '6'
#define MOUSE_DOWN '7'
#define MOUSE_UP '8'
#define MOUSE_SCROLL '9'




void setup() {
  Serial.begin(SERIAL_PORT);
  Mouse.begin();
  Keyboard.begin();
  pinMode(led, OUTPUT);
}

void loop()
{
  char buffer[MAX_BUFFER_SIZE];
  int buffPos = 0;

  while (Serial.available() == 0) {
    delayMicroseconds(SERIAL_DELAY);
  }

  while (Serial.available()) {
    if (buffPos < MAX_BUFFER_SIZE - 1) {
      buffer[buffPos++] = Serial.read();
      buffer[buffPos] = '\0';
    }
    else   // буфер переполнен
    {
      while (Serial.available()) {
        int temp = Serial.read();
      }
      digitalWrite(led, HIGH);
      delay(3000); // 3 секунды будет включен светодиод L
      digitalWrite(led, LOW);
    }
  }



  //digitalWrite(led, HIGH);
  //delay(500); // 3 секунды будет включен светодиод L
  //digitalWrite(led, LOW);



  switch (buffer[0]) {
    case SET_DELAY:  // установки паузы для клавиш клавиутуры и мыши
      {
        switch (buffer[1]) {
          case SET_KEYBOARD_DELAY:
            KEYBOARD_DELAY = atoi(&buffer[2]);
            break;
          case SET_MOUSE_DELAY:
            MOUSE_DELAY = atoi(&buffer[2]);
            break;
        }
        break;
      }
    case PRESS_KEY:  // нажатие клавиши
      {
        char key = atoi(&buffer[1]);
        Keyboard.press(key);
        delay(KEYBOARD_DELAY);
        Keyboard.release(key);
        delay(KEYBOARD_DELAY);
        break;
      }
    case PRINT_STRING:  // напечатать строку
      {
        for (int i = 1; i < buffPos; i++) {
          Keyboard.write(buffer[i]);
          delay(KEYBOARD_DELAY);
        }
        break;
      }
    case KEY_DOWN:  // зажать клавишу
      {
        Keyboard.press(atoi(&buffer[1]));
        delay(KEYBOARD_DELAY);
        break;
      }
    case KEY_UP:  // отпустить клавишу
      {
        Keyboard.release(atoi(&buffer[1]));
        delay(KEYBOARD_DELAY);
        break;
      }
    case MOUSE_MOVE:  // переместить курсор мыши
      {
        long coordinate = atol(&buffer[3]);

        // x и y на сколько пикселей нужно сместить курсор
        long x = coordinate / 65535;
        long y = coordinate % 65535;

        // нужно двигать влево/вправо вверх/вниз
        if (buffer[1] == '-')
          x = -x;
        if (buffer[2] == '-')
          y = -y;

        // сколько нужно сделать шагов
        int count_step;
        int stepX = 127, stepY = 127;        // шаг
        int remainsX, remainsY;  // сколько останется в конце

        if (abs(x) > abs(y))  // если по X больше двигать курсор чем по Y
        {
          count_step = abs(x) / 127;
          if (count_step > 0)
          {
            if (x < 0)stepX = -127;

            if (y > 0)stepY = abs(y) / count_step;
            else stepY = y / count_step;

            if (abs(stepY) > 127)
            {
              if (stepY > 0)stepY = 127;
              else stepY = -127;
            }
          }
          remainsX = x % stepX;
          remainsY = y % stepY;
        }
        else
        {
          count_step = abs(y) / 127;
          if (count_step > 0)
          {
            if (y < 0)stepY = -127;
            if (x > 0)stepX = abs(x) / count_step;
            else stepX = x / count_step;

            if (abs(stepX) > 127)
            {
              if (stepX > 0)stepX = 127;
              else stepX = -127;
            }
          }
          remainsX = x % stepX;
          remainsY = y % stepY;
        }


        for (int i = 0; i < count_step; i++)  // перемещение курсора
        {
          Mouse.move(stepX, stepY, 0);
        }

        Mouse.move(remainsX, remainsY, 0);  // перемещение в конечную точку
        break;
      }
    case MOUSE_CLICK:  // клик кнопкой мыши
      {
        Mouse.click(buffer[1]);
        delay(MOUSE_DELAY);
        break;
      }
    case MOUSE_DOWN:  // зажать кнопку мыши
      {
        Mouse.press(buffer[1]);
        delay(MOUSE_DELAY);
        break;
      }
    case MOUSE_UP:  // отпустить кнопку мыши
      {
        Mouse.release(buffer[1]);
        delay(MOUSE_DELAY);
        break;
      }
    case MOUSE_SCROLL:  // скролл мыши
      {
        char wheel = atoi(&buffer[1]);
        Mouse.move(0, 0, wheel);
        delay(MOUSE_DELAY);
        break;
      }
    default:
      break;
  }
  Serial.print("ready");
}