Duel stone, очень надо плиззз Опции

[Revolver]

Народ подскажите почему в этом скрипте когда игроки телепортируются на арену у них исчезают вещи из сумки

ВОТ САМ СКРИПТ

Код

[ITEMDEF i_stone_duel]
DEFNAME=i_stone_duel
ID=0ed6
NAME=duel stone
TYPE=t_eq_script
CATEGORY=Add Items
SUBSECTION=Stones
DESCRIPTION=Duel stone

ON=@Create
COLOR=0425    // 0425 - Свободен, 0 - Возможно занят, 0423 - Занят.
ATTR=attr_static|attr_move_never|attr_newbie
MORE1=0       // Переменная которю будет юзать таймер камня для отсчёта времени.
MORE2=0   // Бабло нужное для дуэли, если 0 то бабло не надо.
MOREX=4445
MOREY=1171
MOREZ=1
TAG.TIME=3    // Время в минутах на подготовку(одеватся тама, макры настраивать)
TAG.ACTION=0  // Действия камня по истичению таймера камня.

ON=@Click
IF (<EVAL <MORE2>>==0)
   NAME=duel stone
ELSE
   NAME=duel stone - <EVAL <MORE2>> gp
ENDIF

ON=@DClick
IF (<SRC.IsGM> ) && (<SRC.TARG.TOPOBJ.UID>==<SRC.UID> )
   SRC.SYSMESSAGE New coordinates on dule set: <SRC.P>
   MOREP=<SRC.P>
   RETURN 1
ENDIF

IF (<SRC.TARG.TOPOBJ.DISTANCE> > 3)
   SRC.SYSMESSAGE You can't reach that.
   RETURN 1
ENDIF

IF (<MOREX>==0) && (<MOREY>==0) && (<MOREZ>==0)
SRC.SYSMESSAGE Duel stone not worked. Please call GM.
RETURN 1
ENDIF

IF !(<EVAL <TAG.TIME>> )
   SRC.SYSMESSAGE Duel stone not worked. Please call GM.
   RETURN 1
ENDIF

IF (<COLOR>==0423) || (<EVAL <COLOR>>==0)
   SRC.SYSMESSAGE The arena of duels is occupied.
   RETURN 1
ENDIF

IF (<SRC.FINDLAYER.25.UID> )
   SRC.SYSMESSAGE You can't fight on the animal.
   RETURN 1
ENDIF
IF (<SRC.FINDLAYER.1.UID> ) || (<SRC.FINDLAYER.2.UID> ) || (<SRC.FINDLAYER.3.UID> ) || (<SRC.FINDLAYER.4.UID> ) || (<SRC.FINDLAYER.5.UID> ) || (<SRC.FINDLAYER.6.UID> ) || (<SRC.FINDLAYER.7.UID> ) || (<SRC.FINDLAYER.8.UID> ) || (<SRC.FINDLAYER.10.UID> ) || (<SRC.FINDLAYER.12.UID> ) || (<SRC.FINDLAYER.13.UID> ) || (<SRC.FINDLAYER.14.UID> ) || (<SRC.FINDLAYER.17.UID> ) || (<SRC.FINDLAYER.18.UID> ) || (<SRC.FINDLAYER.19.UID> ) || (<SRC.FINDLAYER.20.UID> ) || (<SRC.FINDLAYER.22.UID> ) || (<SRC.FINDLAYER.23.UID> ) || (<SRC.FINDLAYER.31.UID> )
   SRC.SYSMESSAGE You must undress before duel.
   RETURN 1
ENDIF
IF (<EVAL <MORE2>>!=0)
   IF (<SRC.FINDLAYER.21.RESCOUNT> > 1) 
      SRC.SYSMESSAGE You must clear your backpack.
      RETURN 1
   ENDIF
   IF (<SRC.FINDLAYER.21.FINDCONT.0.TYPE>!=t_gold) && (<SRC.FINDLAYER.21.FINDCONT.0.AMOUNT> < <EVAL <MORE2>> )
      SRC.SYSMESSAGE You must have <EVAL <MORE2>> gp for duel.
      RETURN 1
   ENDIF
ELSE
   IF (<SRC.FINDLAYER.21.RESCOUNT>!=0) 
      SRC.SYSMESSAGE You must clear your backpack.
      RETURN 1
   ENDIF
ENDIF

TARGET Who will participate in a duel?
RETURN 1

ON=@TargON_Item
SRC.SYSMESSAGE You can not with a item.
RETURN 1

ON=@TargON_Char
IF (<SRC.TARG.UID>==<SRC.UID> )
   SRC.SYSMESSAGE You can't duel against youself.
ELIF (<SRC.TARG.DISTANCE> > 4)
   SRC.SYSMESSAGE <SRC.TARG.NAME> far away for duel.
ELIF (<SRC.TAG0.DUEL_ARENA> )
   SRC.SYSMESSAGE <SRC.TARG.NAME> already accepting duel.
ELIF (<SRC.TARG.NPC> )
   SRC.SYSMESSAGE You can't duel against a NPC.
ELIF (<SRC.TARG.FINDLAYER.25.UID> )
   SRC.SYSMESSAGE <SRC.TARG.NAME> can't fight on the animal.
ELIF (<SRC.TARG.FINDLAYER.1.UID> ) || (<SRC.TARG.FINDLAYER.2.UID> ) || (<SRC.TARG.FINDLAYER.3.UID> ) || (<SRC.TARG.FINDLAYER.4.UID> ) || (<SRC.TARG.FINDLAYER.5.UID> ) || (<SRC.TARG.FINDLAYER.6.UID> ) || (<SRC.TARG.FINDLAYER.7.UID> ) || (<SRC.TARG.FINDLAYER.8.UID> ) || (<SRC.TARG.FINDLAYER.10.UID> ) || (<SRC.TARG.FINDLAYER.12.UID> ) || (<SRC.TARG.FINDLAYER.13.UID> ) || (<SRC.TARG.FINDLAYER.14.UID> ) || (<SRC.TARG.FINDLAYER.17.UID> ) || (<SRC.TARG.FINDLAYER.18.UID> ) || (<SRC.TARG.FINDLAYER.19.UID> ) || (<SRC.TARG.FINDLAYER.20.UID> ) || (<SRC.TARG.FINDLAYER.22.UID> ) || (<SRC.TARG.FINDLAYER.23.UID> ) || (<SRC.TARG.FINDLAYER.31.UID> )
   SRC.SYSMESSAGE <SRC.TARG.NAME> must undress before duel.
ELIF (<SRC.TARG.FINDLAYER.21.RESCOUNT> > 0) 
   SRC.SYSMESSAGE <SRC.TARG.NAME> must clear backpack.
ELSE
   // Ставим на камень цвет говорящий о том что камень возможно будет занят.
   COLOR=0
   TIMER=60

   // Ставим тег на игрока, о том что он хочет начать дуель.
   SRC.TAG.DUEL_ARENA=1

   // Таймер который создаёт другой таймер для диалога
   SRC.NEWITEM=i_duel_dialog_runner
   SRC.ACT.CONT=<SRC.TARG.UID>
   SRC.ACT.TAG.StoneUID=<UID>              // UID Камня
   SRC.ACT.TAG.Player1UID=<SRC.UID>        // UID игрока который предлагает бой
   SRC.ACT.TAG.Player2UID=<SRC.TARG.UID>   // UID игрока которому предлагают бой
   SRC.ACT.TIMER=0
   TAG.Player1UID=<SRC.UID>
   TAG.Player2UID=<SRC.TARG.UID>
ENDIF
RETURN 1

ON=@Timer
IF (<COLOR>==0)
   COLOR=0425
   TIMER=-1
   RETURN 1
ENDIF
IF (<EVAL <TAG.ACTION>>==0) // Выдача вещей и установка флагов и времени на подготовку
   LINK=<TAG.Player1UID>
   // Кидаем игрока на арену...
   LINK.GO <EVAL <MOREX>+3> <EVAL <MOREY>-3> <MOREZ>
   // Говорим игрокам что у них скока то минут на подготовку
   LINK.MESSAGE <EVAL <TAG.TIME>> minutes for preparing...
   // Снимает с игрока временный stone
   LINK.FLAGS=<LINK.FLAGS>&~statf_stone
   // Ставим на него только инвул чтоб не отакавал раньше времени
   LINK.FLAGS=<LINK.FLAGS>|statf_invul
   // Удаляем живность с игрока - если даже он как то залез
   IF (<LINK.FINDLAYER.25> )
      LINK.FINDLAYER.25.REMOVE
   ENDIF
   // Выдаём вещи игроку
   IF !(<LINK.FINDLAYER.21.UID> )
      LINK.NEWITEM=i_backpack
      LINK.ACT.EQUIP
      LINK.ACT.CONT=<LINK.UID>
   ENDIF

   LINK.f_give_duel_armor <LINK.UID>
   LINK.UPDATE
   LINK.RESEND

   LINK=<TAG.Player2UID>
   // Кидаем игрока на арену...
   LINK.GO <EVAL <MOREX>-3> <EVAL <MOREY>+3> <MOREZ>
   // Говорим игрокам что у них скока то минут на подготовку
   LINK.MESSAGE <EVAL <TAG.TIME>> minutes for preparing...
   // Снимает с игрока временный stone
   LINK.FLAGS=<LINK.FLAGS>&~statf_stone
   // Ставим на него только инвул чтоб не отакавал раньше времени
   LINK.FLAGS=<LINK.FLAGS>|statf_invul
   // Удаляем живность с игрока - если даже он как то залез
   IF (<LINK.FINDLAYER.25> )
      LINK.FINDLAYER.25.REMOVE
   ENDIF
   // Выдаём вещи игроку
   IF !(<LINK.FINDLAYER.21.UID> )
      LINK.NEWITEM=i_backpack
      LINK.ACT.EQUIP
      LINK.ACT.CONT=<LINK.UID>
   ENDIF

   LINK.f_give_duel_armor <LINK.UID>
   LINK.UPDATE
   LINK.RESEND

   // Ставим на отсчёт времени на подготовку...
   MORE1=<EVAL <TAG.TIME>*60>
   TAG.ACTION=1
   TIMER=1
   RETURN 1
ENDIF
IF (<EVAL <TAG.ACTION>>==1) // Отсчёт времени до начала самого боя
   IF (<EVAL <MORE1>> )
      IF (<EVAL <MORE1>>==60)
         LINK=<TAG.Player1UID>
         LINK.SYSMESSAGE One minute before a duel.
         LINK=<TAG.Player2UID>
         LINK.SYSMESSAGE One minute before a duel.
      ELIF (<EVAL <MORE1>>==30)
         LINK=<TAG.Player1UID>
         LINK.SYSMESSAGE There were 30 seconds before duel.
         LINK=<TAG.Player2UID>
         LINK.SYSMESSAGE There were 30 seconds before duel.
      ELIF (<EVAL <MORE1>> < 11)
         LINK=<TAG.Player1UID>
         LINK.SYSMESSAGE There were <EVAL <MORE1>> seconds before duel.
         LINK=<TAG.Player2UID>
         LINK.SYSMESSAGE There were <EVAL <MORE1>> seconds before duel.
      ENDIF
      MORE1=<MORE1>+-1
   ELSE
      LINK=<TAG.Player1UID>
      LINK.FLAGS=<LINK.FLAGS>&~statf_invul
      LINK.MESSAGE FIGHT!
      LINK=<TAG.Player2UID>
      LINK.FLAGS=<LINK.FLAGS>&~statf_invul
      LINK.MESSAGE FIGHT!
      TAG.ACTION=2
   ENDIF
   LINK=<TAG.Player1UID>
   IF !StrMatch("Duel Pits","<LINK.REGION.NAME>")
      TAG.ACTION=3
   ENDIF
   LINK=<TAG.Player2UID>
   IF !StrMatch("Duel Pits","<LINK.REGION.NAME>")
      TAG.ACTION=3
   ENDIF
   TIMER=1
   RETURN 1
ENDIF
IF (<EVAL <TAG.ACTION>>==2) // Проверяем может кто умер..
   LINK=<TAG.Player1UID>
   IF (<LINK.HITS>==0)
      LINK.EMOTE lose.
      LINK=<TAG.Player2UID>
      LINK.EMOTE winner
      SAY <SERV.UID.<TAG.Player1UID>.NAME> lose. <SERV.UID.<TAG.Player2UID>.NAME> Win.
      TAG.ACTION=4
   ENDIF
   IF !StrMatch("Duel Pits","<LINK.REGION.NAME>")
      TAG.ACTION=4
   ENDIF
   LINK=<TAG.Player2UID>
   IF (<LINK.HITS>==0)
      LINK.EMOTE lose.
      LINK=<TAG.Player1UID>
      LINK.EMOTE winner
      SAY <SERV.UID.<TAG.Player2UID>.NAME> lose. <SERV.UID.<TAG.Player1UID>.NAME> Win.
      TAG.ACTION=4
   ENDIF
   IF !StrMatch("Duel Pits","<LINK.REGION.NAME>")
      TAG.ACTION=4
   ENDIF
   TIMER=4
   RETURN 1
ENDIF
// Возвращяем игроков на маркет или куда тама и освобождаем камень
   TAG.ACTION=
   LINK=<TAG.Player1UID>
   LINK.f_remove_trade_window
   LINK.FINDLAYER.31.REMOVE
   LINK.UNDRESS
   LINK.FINDLAYER.21.EMPTY
   IF StrMatch("Duel Pits","<LINK.REGION.NAME>")
      LINK.HITS=<LINK.STR>
      LINK.BODY=<LINK.OBODY>
      LINK.COLOR=<LINK.OSKIN>
      IF (<LINK.FLAGS>&statf_dead)
         LINK.FLAGS=<LINK.FLAGS>&~statf_dead
      ENDIF
      IF (<LINK.FLAGS>&statf_insubstantial)
         LINK.FLAGS=<LINK.FLAGS>&~statf_insubstantial
      ENDIF
      IF (<LINK.FLAGS>&statf_invul)
         LINK.FLAGS=<LINK.FLAGS>&~statf_invul
      ENDIF
      LINK.FINDLAYER.21.EMPTY
      LINK.FINDLAYER.22.REMOVE
//      LINK.FINDLAYER.25.REMOVE
      LINK.UPDATE
      LINK.GO MARKET
   ENDIF
   LINK=<TAG.Player2UID>
   LINK.f_remove_trade_window
   LINK.FINDLAYER.31.REMOVE
   LINK.UNDRESS
   LINK.FINDLAYER.21.EMPTY
   IF StrMatch("Duel Pits","<LINK.REGION.NAME>")
      LINK.HITS=<LINK.STR>
      LINK.BODY=<LINK.OBODY>
      LINK.COLOR=<LINK.OSKIN>
      IF (<LINK.FLAGS>&statf_dead)
         LINK.FLAGS=<LINK.FLAGS>&~statf_dead
      ENDIF
      IF (<LINK.FLAGS>&statf_insubstantial)
         LINK.FLAGS=<LINK.FLAGS>&~statf_insubstantial
      ENDIF
      IF (<LINK.FLAGS>&statf_invul)
         LINK.FLAGS=<LINK.FLAGS>&~statf_invul
      ENDIF
      LINK.FINDLAYER.21.EMPTY
      LINK.FINDLAYER.22.REMOVE
      LINK.UPDATE
      LINK.GO MARKET
   ENDIF
   MORE1=0
   LINK=04fffffff
   COLOR=0425
   TIMER=-1
RETURN 1


[ITEMDEF i_duel_dialog_runner]
ID=i_memory
TYPE=t_eq_script
NAME=Duel dialog runner(Not Remove)

ON=@Create
ATTR=attr_decay|attr_newbie|attr_invis

ON=@Unequip
SRC.NEWITEM=i_duel_dialog               // Таймер который показывает диалог
SRC.ACT.TAG.StoneUID=<TAG.StoneUID>     // UID Камня
SRC.ACT.TAG.Player1UID=<TAG.Player1UID> // UID игрока который предлагает бой
SRC.ACT.TAG.Player2UID=<TAG.Player2UID> // UID игрока которому предлагают бой
SRC.ACT.EQUIP                           // Вешаем на игрока которому предлагают бой

ON=@Timer
REMOVE
RETURN 1


[ITEMDEF i_duel_dialog]
ID=i_memory
TYPE=t_eq_script
NAME=Duel dialog (Not Remove)

ON=@Create
ATTR=attr_move_never|attr_newbie|attr_invis

ON=@Equip
SRC.DIALOGCLOSE D_WANT_DUEL
SRC.DIALOG D_WANT_DUEL

ON=@Unequip
LINK=<TAG.StoneUID>
IF !(<EVAL <LINK.COLOR>> )
   LINK.COLOR=0425
ENDIF
LINK=04fffffff


[DIALOG D_WANT_DUEL]
300,280
noclose
gumppic 0 0 2070              // Backgroud
text 28 25 154 0              // Do you want duel?
text 28 45 154 1              // TARG Name
button  35 75 2073 2072 1 0 0 // Cancel
button 100 75 2076 2075 1 0 1 // Okey

[DIALOG D_WANT_DUEL text]
Do you want duel
on <SERV.UID.<FINDID.i_duel_dialog.TAG.Player1UID>.NAME>?


[DIALOG D_WANT_DUEL button]
ON=0
// Ставим на камень цвет говорящий о том что камень не занят.
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.StoneUID>
FINDID.i_duel_dialog.LINK.COLOR=0425

// Пишем тому кто предлагал бой о том что опонент НЕ согласился
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player1UID>
FINDID.i_duel_dialog.LINK.SYSMESSAGE <SERV.UID.<FINDID.i_duel_dialog.TAG.Player2UID>.NAME> has refused from duel.
FINDID.i_duel_dialog.LINK.TAG.DUEL_ARENA=
FINDID.i_duel_dialog.REMOVE
TAG.DUEL_ARENA=
RETURN 1

ON=1
// Если бабло надо то вычетаем из пака игрока...
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.StoneUID>

// Снимаем временные теги на игроках о том что они хотят начать дуель.
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player1UID>
FINDID.i_duel_dialog.LINK.TAG.DUEL_ARENA=
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player2UID>
FINDID.i_duel_dialog.LINK.TAG.DUEL_ARENA=

// Проверяем на trade window и если есть закрываем а потом проверяем пак
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player1UID>
FINDID.i_duel_dialog.LINK.f_remove_trade_window
IF (<FINDID.i_duel_dialog.LINK.FINDLAYER.21.RESCOUNT>!=0)
   FINDID.i_duel_dialog.LINK.SYSMESSAGE You must clear your backpack.
   // Ставим на камень цвет говорящий о том что камень не занят.
   FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.StoneUID>
   FINDID.i_duel_dialog.LINK.COLOR=0425
   FINDID.i_duel_dialog.REMOVE
   RETURN 1
ENDIF

// Проверяем на trade window и если есть закрываем а потом проверяем пак
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player2UID>
FINDID.i_duel_dialog.LINK.f_remove_trade_window
IF (<FINDID.i_duel_dialog.LINK.FINDLAYER.21.RESCOUNT>!=0)
   FINDID.i_duel_dialog.LINK.SYSMESSAGE You must clear your backpack.
   // Ставим на камень цвет говорящий о том что камень не занят.
   FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.StoneUID>
   FINDID.i_duel_dialog.LINK.COLOR=0425
   FINDID.i_duel_dialog.REMOVE
   RETURN 1
ENDIF

// Пишем тому кто предлагал бой о том что опонент согласился
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player1UID>
FINDID.i_duel_dialog.LINK.SYSMESSAGE <SERV.UID.<FINDID.i_duel_dialog.TAG.Player2UID>.NAME> has accepted your duel.

// Ставим на камень таймер о том что бой начнётся!
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.StoneUID>
FINDID.i_duel_dialog.LINK.TIMER=5
// Ставим на камень цвет говорящий о том что камень занят.
FINDID.i_duel_dialog.LINK.COLOR=0423

// Ставим игроков в камень чтоб не убежали и пополняем Hits, Mana, Stam
FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player1UID>
FINDID.i_duel_dialog.LINK.FLAGS=<FINDID.i_duel_dialog.LINK.FLAGS>|statf_stone
FINDID.i_duel_dialog.LINK.HITS=<FINDID.i_duel_dialog.LINK.STR>
FINDID.i_duel_dialog.LINK.STAM=<FINDID.i_duel_dialog.LINK.DEX>
FINDID.i_duel_dialog.LINK.MANA=<FINDID.i_duel_dialog.LINK.INT>
FINDID.i_duel_dialog.LINK.FIX
FINDID.i_duel_dialog.LINK.UPDATE

FINDID.i_duel_dialog.LINK=<FINDID.i_duel_dialog.TAG.Player2UID>
FINDID.i_duel_dialog.LINK.FLAGS=<FINDID.i_duel_dialog.LINK.FLAGS>|statf_stone
FINDID.i_duel_dialog.LINK.HITS=<FINDID.i_duel_dialog.LINK.STR>
FINDID.i_duel_dialog.LINK.STAM=<FINDID.i_duel_dialog.LINK.DEX>
FINDID.i_duel_dialog.LINK.MANA=<FINDID.i_duel_dialog.LINK.INT>
FINDID.i_duel_dialog.LINK.FIX
FINDID.i_duel_dialog.LINK.UPDATE

FINDID.i_duel_dialog.REMOVE
RETURN 1


[FUNCTION f_give_duel_armor]
IF (<ARGN> ) // UID
   NEWITEM=i_spellbook_arena
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=t_tournament_regs
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_arrow,50
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_xbolt,50
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_bandage,50
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_scroll_greater_heal,20
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_scroll_magic_reflection,20
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_scroll_lightning,20
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_scroll_paralyze,20
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_scroll_flamestrike,20
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_potion_RefreshTotal,10
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_potion_HealGreat,10
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
   NEWITEM=i_potion_ManaTotal,10
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_tournament_platemail_chest
   ACT.NAME=duel platemail
   ACT.COLOR=0850
   ACT.EQUIP
   ACT.CONT=<ARGN>
 
   NEWITEM=i_tournament_platemail_arms
   ACT.NAME=duel platemail arms
   ACT.COLOR=0850
   ACT.EQUIP
   ACT.CONT=<ARGN>

   NEWITEM=i_tournament_platemail_leggings
   ACT.NAME=duel platemail leggings
   ACT.COLOR=0850
   ACT.EQUIP
   ACT.CONT=<ARGN>

   NEWITEM=i_tournament_platemail_helm
   ACT.NAME=duel platemail helm
   ACT.COLOR=0850
   ACT.EQUIP
   ACT.CONT=<ARGN>

   NEWITEM=i_tournament_platemail_gorget
   ACT.NAME=duel platemail gorget
   ACT.COLOR=0850
   ACT.EQUIP
   ACT.CONT=<ARGN>

   NEWITEM=i_tournament_platemail_gloves
   ACT.NAME=duel platemail gloves
   ACT.COLOR=0850
   ACT.EQUIP
   ACT.CONT=<ARGN>

   NEWITEM=i_tournament_shield_buckler
   ACT.NAME=duel buckler shield
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_tournament_shield_metal
   ACT.NAME=duel metal shield
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_tournament_shield_heater
   ACT.NAME=duel heater shield
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_tournament_bow
   ACT.NAME=duel bow
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_tournament_crossbow
   ACT.NAME=duel crossbow
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=i_tournament_crossbow_heavy
   ACT.NAME=duel crossbow heavy
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>


   NEWITEM=duel_weapons_s
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=duel_weapons_f
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>

   NEWITEM=duel_weapons_m
   ACT.COLOR=0850
   ACT.CONT=<SERV.UID.<ARGN>.FINDLAYER.21.UID>
ENDIF


[TEMPLATE duel_weapons_m]
DEFNAME=duel_weapons_m
NAME=backpack (MaceFighting)
CATEGORY=Add Tournament
SUBSECTION=Backpack
DESCRIPTION=Weapons (MaceFighting)
CONTAINER=i_backpack
ITEM=i_tournament_mace
NAME=duel mace
COLOR=0850
ITEM=i_tournament_maul
NAME=duel maul
COLOR=0850
ITEM=i_tournament_mace_war
NAME=duel mace war
COLOR=0850
ITEM=i_tournament_hammer_pick
NAME=duel hammer pick
COLOR=0850
ITEM=i_tournament_hammer_war
NAME=duel hammer war
COLOR=0850


[TEMPLATE duel_weapons_s]
DEFNAME=duel_weapons_s
NAME=backpack (Swordsmanship)
CATEGORY=Add Tournament
SUBSECTION=Backpack
DESCRIPTION=Weapons (Swordsmanship)
CONTAINER=i_backpack
ITEM=i_tournament_scimitar
NAME=duel scimitar
COLOR=0850
ITEM=i_tournament_cutlass
NAME=duel cutlass
COLOR=0850
ITEM=i_tournament_sword_viking
NAME=duel viking sword
COLOR=0850
ITEM=i_tournament_katana
NAME=duel katana
COLOR=0850
ITEM=i_tournament_sword_broad
NAME=duel broad sword
COLOR=0850
ITEM=i_tournament_sword_long
NAME=duel long sword
COLOR=0850
ITEM=i_tournament_axe
NAME=duel axe
COLOR=0850
ITEM=i_tournament_axe_exec
NAME=duel executioner's axe
COLOR=0850
ITEM=i_tournament_axe_double
NAME=duel double axe
COLOR=0850


[TEMPLATE duel_weapons_f]
DEFNAME=duel_weapons_f
NAME=backpack (Fencing)
CATEGORY=Add Tournament
SUBSECTION=Backpack
DESCRIPTION=Weapons (Fencing)
CONTAINER=i_backpack
ITEM=i_tournament_kryss
NAME=duel kryss
COLOR=0850
ITEM=i_tournament_pitchfork
NAME=duel pitchfork
COLOR=0850
ITEM=i_tournament_spear
NAME=duel spear
COLOR=0850
ITEM=i_tournament_spear_short
NAME=duel spear short
COLOR=0850
ITEM=i_tournament_war_fork
NAME=duel war fork
COLOR=0850

[DihlofozzZ]

потому что так написано, ищи действия с 21-м лаером и правь на свой лад

[Dark_Falcon]

потому что так написано, ищи действия с 21-м лаером и правь на свой лад

Да я ему уже написал чего искать надо http://forum.uobugs.ru/showthread.php?s=&threadid=11981
(IMG:style_emoticons/default/smile.gif)

[AronaX]

Над ним форум ещё на уо багс стебался, дак он еще сюда лезет!!!