Скрипт Для Кача Опции

[DarkMaster]

скрипт

Код

// Кнопка с макросом /targetnext
set %mob [1] F1
// Кнопки с макросами на таргет мобов.
// При необходимости можно добавлять неограниченное количество.
// Пустые кнопки не оставлять! Если не нужно большое количество
// таргетов - лишние убрать!
set %mob [2] F2
set %mob [3] F3
set %mob [4] F4

// Кнопки со скилами атаки.
// При необходимости можно добавлять неограниченное количество.
// Пустые кнопки не оставлять! Если не нужно большое количество
// скилов - лишние убрать!
set %attack [1] F5
set %attack [2] F6
set %attack [3] F7
set %attack [4] F8

// Кнопка с подбором лута.
set $pickup F9

// Сколько выпавших итемов будет подбирать.
// Если упадет меньше, то все равно будет стоять и тыкать.
set #pickup 4

// Цвет крайней левой точки полоски хп моба.
set #mobColorHP 4474495
// Координата крайней левой точки полоски хп моба.
set #xMobHP 577
set #yMobHP 581

set #mobsize size (%mob)
set #attacksize size (%attack)
set #nMob 1
set #nAttack 1
//msg #mobsize #attacksize

:start
while_not #xMobHP, #yMobHP #mobColorHP  // Пока не увидим хп, ищем моба
    send %mob [#nMob]
    if #nMob < #mobsize
        set #nMob #nMob + 1
    else
        set #nMob 1
    end_if
    wait 500
    wait random (1000)
//    get color #c #xMobHP, #yMobHP
//    msg ищем #mobColorHP нашли #c
end_while

set #nMob 1

while #xMobHP, #yMobHP #mobColorHP // Пока видим хп - лупим
    send %attack [#nAttack]
    if #nAttack < #Attacksize
        set #nAttack #nAttack + 1
    else
        set #nAttack 1
    end_if
    wait 500
    wait random (1000)
end_while

repeat #pickup // Собираем дроп.
    send $pickup
    wait 200
    wait random (500)
end_repeat

goto start

Видеоинструкция от пользователя Auto_BOT

В ТЕМЕ ОБСУЖДАЕТСЯ ТОЛЬКО ДАННЫЙ СКРИПТ.

Сообщение отредактировал DarkMaster - 5.4.2012, 20:28

[Larrikin]

Уменьшил размер окна линейки чуть не до спичечной коробки, на вид окна хп не изменились

(IMG:http://img163.imageshack.us/img163/8146/mobhpwindowsmall.png)