Ускорение работы color, color требует отдельный кадр, можно ли ускорить? Опции

[KudesniK]

Было замечено, что каждый вызов функции color требует отдельный кадр, рассмотрим пример (отключено слежение, задержка 0ms):

Код

set #counter 0
set timer
while 1
    if timer > 1000
        hint #counter
        set timer
        set #counter 0
    end_if

    set #counter #counter + 1
    set #color color (53, 144)
end_while
end_script

в окнах, где используется vsync количество вызовов color будет ограничено частотой экрана, в моем случае 60, в остальных окнах количество вызовов color может доходить до нескольких тысяч.

Таким образом при необходимости анализа шести разных пикселей на цвет, мы получаем падение производительности скрипта до десяти проверок в секунду, при необходимости контролировать десять пикселей, уже шесть операций в секунду.

Например, заменив одну операцию color на (как пример):

Код

if 255, 380 16777215 and 200, 300 15588051 and 12, 27 5621216 and 33, 33 13743257
    send {f1}
end_if

мы получаем падение производительности в четыре раза (четыре вызова color), т.е. до 15 проверок в секунду, пример выше использован для демонстрации. Соответственно при пяти таких блоках производительность уже будет около трех проверок в секунду.

Альтернативный вариант сделать один снимок экрана и в нем искать нужные цвета в нужных пикселях, но я не нашел как взять цвет пикселя в результате работы GetImage.

Может кто сталкивался, подскажите как решали, или как взять цвет пикселя после фотографии экрана.

[KudesniK]

Имеем производительность порядка 1100 пикселей в секунду по сравнению с 60 у get color.
При увеличении области до 800х600 производительность падает до 600 в секунду.
Область 1920х1080 - 400 пикселей в секунду.
"Фотография" экрана происходит для анализа 20 пикселей.

Всем спасибо, с большего меня это решение устраивает, может в будущем что-то переработают, пока живу с вот этим.

Код

set #handle workwindow

set timer

while 1
   if timer > 1000
        hint #counter
        log #counter
        set timer
        set #counter 0
    end_if

    set #counter #counter + 1

    set workwindow #handle
    set %arr GetImage (1 1 200 200)

    set workwindow windowhandle

    for #i 1 20
        set #x random(200)
        set #y random(200)
        // set #x 21
        // set #y 41
        gosub fast_color
        // log #color
    end_for
end_while

:fast_color
    set #z1 %arr [1 1] + %arr [1 4] * (#y - 1) + (#x - 1) * 3
    set #z2 %arr [1 1] + %arr [1 4] * (#y - 1) + (#x - 1) * 3 + 1
    set #z3 %arr [1 1] + %arr [1 4] * (#y - 1) + (#x - 1) * 3 + 2
    readmem #b #z1 b
    readmem #g #z2 b
    readmem #r #z3 b
    set #color #b * 256 * 256 + #g * 256 + #r
return