Подскажите почему move_smooth не работает?, move_smooth в 3D шутере Опции

[SeregaB]

Столкнулся с проблемой в Lua и обычном коде.
В игре Шутере происходит захват мышки и курсор пропадает.
Далее программа находит цель и ее координаты (set #x и set #y)
После чего идет команта сместить "мышу" move_smooth, но экран не поворачивается.
Сам курсор и все нажатия происходят, но экран в игре остается на месте.
Может надо как то прописать имитацию кода физической мышки, чтобы экран в игре поворачивался?
Такое вообще возможно?
Вот сам код на смещение мышки:

set #x 250
set #y 300
Move #x #y
kleft #x #y // кликнули
kleft_down #x #y // зажали ЛКМ
set clickoffsetx 500 // смещение для координаты X
set clickoffsety 50 // смещение для координаты Y
move_smooth #x #y // Переместили курсор
get mouse_pos #x #y // нашли курсор
kleft_up #x #y
end_script

[SeregaB]

Нашел такую функцию и она работает, правда в другой программе.
Экран поворачивается на заданное растояние

Код

Func _MouseMovePlus($X, $Y,$absolute = 0)
        Local $MOUSEEVENTF_MOVE = 1
    Local $MOUSEEVENTF_ABSOLUTE = 32768
    DllCall("user32.dll", "none", "mouse_event", _
            "long",  $MOUSEEVENTF_MOVE + ($absolute*$MOUSEEVENTF_ABSOLUTE), _
            "long",  $X, _
            "long",  $Y, _
            "long",  0, _
        "long",  0)
EndFunc

Так тоже работает

Код

Func _MouseMovePlus($X, $Y,$absolute = 0)
        Local $MOUSEEVENTF_MOVE = 1
        DllCall("user32.dll", "none", "mouse_event", _
            "long",  $MOUSEEVENTF_MOVE, _
            "long",  $X, _
            "long",  $Y, _
            "long",  0, _
        "long",  0)
EndFunc

Скажите пожалуйста, как подобное можно реализовать в Пилоте?
Как я и предполагал, через вызов DDL все работает.

[Fors1k]

Скажите пожалуйста, как подобное можно реализовать в Пилоте?
Как я и предполагал, через вызов DDL все работает.

Ну, походу, то, что ты хотел.

Код

//...
call move 100 -50      // сдвинуть курсор на 100 вправо и на 50 вверх
wait 2000
call move -100 50      // вернуть курсор обратно
wait 2000
call move 1100 500 abs // передвинуть курсор в кординаты 1100 500
//...
end_script
proc move #x #y $abs
set linedelay 0
set #flags 1
if $abs = abs
set #flags 32769
set #x 65536 * #x / screenwidth
set #y 65536 * #y / screenheight
end_if
exec winapiexec.exe u@mouse_event #flags #x #y 0 0
end_proc

Файл закинь в /System32.

[SeregaB]

Ну, походу, то, что ты хотел.

Файл закинь в /System32.

Отлично, спасибо, теперь получился поворот экрана, только не понятно что это за файл и как его делать под себя, если понадобятся другие задачи. Как я понимаю, в Пилоте напрямую через DLL нельзя прописать такую функцию?

[Fors1k]

Отлично, спасибо, теперь получился поворот экрана, только не понятно что это за файл и как его делать под себя, если понадобятся другие задачи.

В смысле как запускать другие функции winapi? Я думал тебе только move был нужен, и написал удобную процедуру именно под него. Можно и универсальную сделать.
Для любой функции winapi: call winApi <библиотека> <функция> <параметры(одной переменной)> .
А можно и совместить, если move все-таки будет использоваться в коде часто.
Пример:

Код

set $params 1 -300 -250 0 0
call winapi u mouse_event $params              // сдвинуть курсор на 300 влево и на 250 вверх
wait 1000

call move 300 250                              // вернуть курсор обратно    (КОРОТКАЯ ЗАПИСЬ)
wait 2000
call move 500 500 abs                          // сдвинуть курсор в 500x500 (КОРОТКАЯ ЗАПИСЬ)

set $params 0 open calc.exe 0 0 1
call winapi s ShellExecuteW $params            // запустить калькулятор
wait 4000

set $params findwindow('калькулятор') 16 0 0
call winapi u SendMessageW $params             // закрыть калькулятор

end_script

//---------------------------------------------

proc winapi $lib $function $params
set linedelay 0
switch $lib
case u
exec winapiexec.exe user32.dll@$function $params
break
case s
exec winapiexec.exe shell32.dll@$function $params
break
end_switch
end_proc
proc move #x #y $abs
set linedelay 0
set #flags 1
if $abs = abs
set #flags 32769
set #x 65536 * #x / screenwidth
set #y 65536 * #y / screenheight
end_if
exec winapiexec.exe u@mouse_event #flags #x #y 0 0
end_proc

Скорее всего кстати файлик закинуть можно и просто рядом с пилотом.

Ага, можно куда угодно. Просто в s32 удобно, что бы путь не писать каждый раз)

Потому что я малость не шарю в винапи

Да я сам впервые вижу этот вин апи, и уже начинаю его недолюбливать))

[SeregaB]

Да я сам впервые вижу этот вин апи, и уже начинаю его недолюбливать))

Хоть и впервые, но уже много чего можешь сделать. Я совсем не представляю откуда брать параметры и как это все на деле применять. В разных программах все по разному, конкретного описапия нигде не нашел.
Просто с применением WinApi расширяется круг возможностей, пример тому решилась моя задача.

Fors1k, единственное есть вопрос, как можно сделать плавное смещение курсора командой call move x y?

[Fors1k]

Fors1k, единственное есть вопрос, как можно сделать плавное смещение курсора командой call move x y?

Код

wait 500
set linedelay 0
call move -500 -230           // сдвинуть курсор на 500 влево и на 230 вверх

wait 1200

call movesmooth 500 230       // плавно вернуть курсор обратно

end_script

//----------------------------

proc movesmooth #x #y
set #cf 12
set #cx #x / #cf
set #cy #y / #cf
repeat #cf
call move #cx #cy
end_repeat
set #fx #x - #cx * #cf
set #fy #y - #cy * #cf
call move #fx #fy
end_proc

proc move #x #y $abs
set linedelay 0
set #flags 1
if $abs = abs
set #flags 32769
set #x 65536 * #x / screenwidth
set #y 65536 * #y / screenheight
end_if
exec winapiexec.exe u@mouse_event #flags #x #y 0 0
end_proc

[Zenogiasu]

Очень странно... Такая сверхважная весчь, как перемещение камеры вместе с курсором в играх с нонтаргетом... описывается только в 1 захолустной темке на форуме, которую случайно нашел. Был уверен что пилотик на такое не способен, и придется учитться работать с ардуино, ведь утвержалось так, будто лишь только через этот дополнительный костыль в виде платы можно двигать камеру. Но тут приходит уважаемый Fors1k, пишет какой-то файлик и О ЧУДО! Пилот из простого-умного манипулятора мышкой превращается в полноценную программу для написания серьезных ботов в современных играх с нонтаргетом, а не только в браузерках и уо, где только курсором и нужно управлять) Спасибо.
Уже собирался заказывать ардуино, хорошо что темку откапал вовремя