Exping.txt Опции

[Larrikin]

Похоже рефакторинг это как ремонт - нельзя закончить, можно прекратить.

Скрипт для ма/дд, пауза между строк - 1 ms.

Общая логика работы скрипта

Скрипт работает пока окошко таргета развернуто. Как только видит свернутое окошко таргета - останавливается.
Сначала скрипт привязывается к последнему окну линейки
Потом проверяет включена ли нужная панель. Это делается с помощью посыла кнопки макроса /taget %self и поиска синих кружочков, которые появляются вокруг головы персонажа при выборе самого себя. Это сделано потому, что обычно кач на скрипте идёт на особой панели.
Потом скрипт ищет сам начало и конец полоск ХП и МП. Проверяет стабильность правой границы - чтобы хп не росло. Эти значения потом используются для анализа ХП мобов.
Потом скрипт зацикливается на выборе и атаке моба.

exping.txt

Код

///////////////////////////////////////////////////
// exping script
set linedelay 1 // установить время задержки между строк


///////////////////////////////////////////////////
// Спот
set #AgrFarDamaged 0             // Трогать ли далеких недобитков
set #postmortem_duration 2222    // Время действия макроса свежевания
set #MaxTargeting 77777          // Сколько времени пытаться взять таргет
set #MaxTimeToKill 99999         // Сколько времени ждать падения моба
set #NewMobFirstBoodTime 7777    // За сколько моб должен повредиться
set #CloseOnlyTime 22222         // Сколько искать вблизи после фейла атаки
set #AtackMacrosWorkTime 2222    // Сколько времени макросу атаки

///////////////////////////////////////////////////
// Персонаж
set $self F11                    // Кнопка с макросом /target %self
set $attack F1                   // Кнопка атаки
set #attack 2222                 // Время между простыми атаками
set $macro_attack F2             // Кнопка с макросом начала атаки
set $debuf 3                     // Кнопка дебафа цели
set #debuf 8000                  // Время отката дебафа
set #re_debuf 30000              // Время до следуюего дебафа
set #overhit 1                   // Оставлять пикселов на добивание
set $overhit F1                  // Кнопка добивания
set #overhit_casting 1111        // Время добивания
set $next F4                     // Кнопка с макросом /targetnext
set $mob F3                      // Кнопка с выбором моба
set $postmortem F7               // Макрос свежевания после убийства
set $self_buf F8                 // Кнопка селф бафа
set #self_buf_casting 1111       // Время на селф бафание
set #self_rebuf 77777            // Через сколько селф ребаф

///////////////////////////////////////////////////
// Константы
set #DeadTargetDelay 7000        // Сколько висит окошко трупа
set #DrawingTargetTime 2222      // Максимальное время появления таргета
set #ColorAlive 1251183          // Цвет жизни
set #ColorAlive2 1316719         // Цвет жизни тоже
set #ColorAliveClose 1316976     // Цвети жизни при смерти
set #ColorMP 8535813             // Цвет маны
set #xMobLeft 0   //  Будет абсолютный Х начала полосок ХП/МП цели
set #xMobOver 0   //  Будет абсолютный Х моба на добивание overhit
set #xMobRight 0  //  Будет абсолютный Х конца полосок ХП/МП цели
set #xMobHigh 0   //  Будет абсолютный Х у конца полосок ХП/МП цели
set #yMobHP 0     //  Будет абсолютный Y полоски ХП цели
set #yMobMP 0     //  Будет абсолютный Y полоски МП цели

// set logging close
gosub set_log_on
gosub lock_window
gosub set_target_window

set timer 0
set #OnlyCloseSelect ( timer + #CloseOnlyTime )
while 1
    gosub target_next
    gosub self_buf
    gosub attack
end_while
//gosub clicker

end_script

///////////////////////////////////////////////////
// селф бафы
:self_buf
if timer > #time_to_self_buf
    send $self_buf                             // Баф - залог победы
// Когда следующий
    set #time_to_self_buf ( timer + #self_rebuf )
    wait #self_buf_casting                 // Время на каст селф бафов
end_if
return

///////////////////////////////////////////////////
// Атака цели
:attack
set #MobCount ( #MobCount +1)     // Раз уж будем его бить
send $macro_attack                         // Пытаемся начать атаку
set #attack_start timer
if timer > #debuf_reuse                    // Дебаф был в откате 
    set #time2re_debuf ( timer + #re_debuf ) // Когда обновлять дебаф
    set #debuf_reuse ( timer + #debuf )      // Когда откатится дебаф
else
    set #time2re_debuf #debuf_reuse  // Дебафнуть по откату сразу
end_if
//wait random (555)                            // Время развернуться к цели
//send home                                     // Разворачиваем экран
set #FirstBloodTime ( #attack_start + #NewMobFirstBoodTime )
if #mob_is_far > 0                // Моб идёт издалека
    set #AttackMacrosEnd ( #attack_start  + #AtackMacrosWorkTime )
else
    set #AttackMacrosEnd ( #attack_start  + 2222 ) // Некогда особо
end_if
get color #Color #xMobLeft #yMobHP        // Начало полоски ХП цели
while #Color = #ColorAlive or #Color = #ColorAlive2 // Ждем падения моба
    if timer > #FirstBloodTime                 // Пора покоцать хоть децл
        get color #Color #xMobHigh #yMobHP        // У правого края ХП
        if #Color = #ColorAlive or #Color = #ColorAlive2 // Моб всё ещё здоров
            set logging Моб #MobCount не коцается, цвет у правой границы #Color
            alarm
            set #OnlyCloseSelect ( timer + #CloseOnlyTime  )    // Потыкай /targetnext
            set #MobCount ( #MobCount - 1)     // Раз уж НЕ будем его бить
            send escape // снимаем таргет
            wait 555
            return                     // Этого моба больше не пытаемся бить
        end_if
    end_if
    if timer > #AttackMacrosEnd   // Макрос атаки выполнен
        if timer > #time2re_debuf  // Пора обновить дебаф
            send $debuf             // Дебафаем
            set #time2re_debuf ( timer + #re_debuf ) // Когда обновлять дебаф
            set #debuf_reuse ( timer + #debuf )      // Когда откатится дебаф
        else
            if timer > #time_to_reattack
                send $attack              // Просто долбим
                set #time_to_reattack ( timer + #attack )
            end_if
       end_if
    end_if
// Ищем раскрытое окошко таргета
    set $target findimage (0 0 111 222 (FindImage\L2\LTargetBig.bmp) %Target 2 90 1)
    if $target < 90 // Если раскрытого окошка таргета нет
        gosub check_close_exit
    end_if
//    wait 111                         // Разбавляем
    set #attack_duration ( timer - #attack_start )
    if #attack_duration > #MaxTimeToKill
        set logging За время #MaxTimeToKill моб #MobCount не упал
        goto error_exit
    end_if
    get color #Color #xMobOver #yMobHP        // Начало полоски ХП цели
end_while // Моб упал сраженный или находится при смерти

send $overhit
wait #overhit_casting
wait random ( 111 )

set #OnlyCloseSelect ( timer + #DeadTargetDelay  + random ( 55 ) )
set #AverageTimePerMob ( timer / #MobCount )
set #AverageMobsPerHour ( ( #MobCount * 1000 *60 * 60 ) / timer )
set logging Моб #MobCount за #attack_duration ms, средний цикл: #AverageTimePerMob или #AverageMobsPerHour мобов/час

send $postmortem   // Мародёрствуем
wait #postmortem_duration                 // Даём на это время

return                       // С этим всё

///////////////////////////////////////////////////
// Наведение на моба
:target_next
set #TargetingTimeOut ( timer + #MaxTargeting + #DrawingTargetTime )
while timer < #TargetingTimeOut    // Ищем цель сколько можно
    if timer < #OnlyCloseSelect        // Окошко трупа ещё висит?
        send $next // Пытаемся взять таргет на очередного моба
        set #mob_is_far 0
        set #delay ( 555 + random ( 222 ) )
    else                                       // Окошку трупа пора пропасть
        send $mob                         // Берём таргет на дальнего моба
        set #mob_is_far 1
        set #delay ( 1111 + random ( 1111 ) )
//        set logging Берем таргет дальним макросом
    end_if                        
// Крайний срок появления таргета после нажатия макроса
    set #MustDraw ( timer + #DrawingTargetTime ) 

    while timer < #MustDraw             // Ищем цель не дольше разрешённого
        wait 222  // Даем время успокоится картинке
        set $target findimage (0 0 111 222 (FindImage\L2\LTargetBig.bmp) %Target 2 90 1)
        if $target > 90 // Если окошко раскрытого таргета есть
            get color #hpColorMin #xMobLeft #yMobHP        // Начало полоски ХП цели
            get color #hpColorHigh #xMobHigh #yMobHP        // У конца полоски ХП цели
            get color #mpColorMin #xMobLeft #yMobMP        // Начало полоски МП цели
            if_not #mpColorMin = #ColorMP                             // Цель - моб или нпц
                if #hpColorHigh = #ColorAlive or #hpColorHigh = #ColorAlive2    // Моб здоров, можно бить
                    return                                                            // Цель предоставлена
                else
                    if #hpColorMin = #ColorAlive or #hpColorMin = #ColorAlive2    // Моб недобиток
                        if #mob_is_far > 0                             // Дальний недобиток
                            if #AgrFarDamaged > 0                 // Можно трогать
                                return    // Цель предоставлена
                            else                                    // Нельзя трогать
                                set logging Дальний моб оказался недобитком
                                alarm
                                set #OnlyCloseSelect ( timer + #CloseOnlyTime  )    // Потыкай /targetnext
                                send escape                     // снимаем таргет
                            end_if                                 // Разобрались с дальним недобитком
                        else                                        // Недобиток оказался ближним
                            return                                // Цель предоставлена
                        end_if                                    // Разобрались с ближним недобитком
                    end_if                                        // Разобрались с недобитком
                end_if                                            // Разобрались с мобом
            end_if                                                // Разобрались с таргетом
        else
            gosub check_close_exit
        end_if
    end_while    // Цель не найдена, пробуем ещё раз

    gosub check_close_exit // Время появления окошка вышло
    send $postmortem   // Мародёрствуем
end_while                                                    // За этот клик макроса цель не найдена

set logging За время #MaxTargeting не взялся таргет
goto error_exit
return    // Никогда здесь не должны оказаться

///////////////////////////////////////////////////
// Захватываем последнее окно линейки
:lock_window
set #handleWin findwindow (Lineage II)
set workwindow #handleWin
wait 555                    // даём время пролагаться


return
///////////////////////////////////////////////////
// Открываем окно логов
:set_log_on
set logging clear                                     // очищаем


///////////////////////////////////////////////////
// Находим начало и конец хп таргета
:set_target_window
send escape // снимаем таргеты
send $self // берём таргет на себя
wait 1111                                // даём время пролагаться


// Синие кружочки должны быть видны
set $blue findimage (0 0 1920 1024 (FindImage\L2\LTargetBlue.bmp) %Blue 2 90 1)
if $blue < 90 // Если синий кружок не виден это конец
        set logging Не виден синий кружок после /target %self - не та панель?
        goto error_exit
end_if

// Должно появиться раскрытое окно таргета
set $target findimage (0 0 111 222 (FindImage\L2\LTargetBig.bmp) %Target 2 90 1)
if $target < 90 // Если не видно раскрытого окна таргета
        set logging Не видно развернутое окошко таргета после /target %self
        goto error_exit
end_if

// Ищем левый край полоски хп
set #yMobHP %Target [ 1 2 ] + 20        //  Абсолютный Y полоски ХП цели
set #xMobLeft %Target [ 1 1 ] + 18        //  Абсолютный Х начала полоски ХП цели
set #x #xMobLeft 
get color #Color #x #yMobHP
while #Color = #ColorAlive or #Color = #ColorAlive2
    set #xMobLeft #x                              //  Уточняем начало полоски ХП цели
    set logging Установили левую границу полоски ХП на #xMobLeft #yMobHP 
    set #i (#i + 1)
    set #x (#x - 1)
    get color #Color #x #yMobHP
//    set logging Левее текущей границы в точке #x #yMobHP цвет #Color 
//    move #x #yMobHP
end_while
if #i < 1
    set logging Проблемы с поиском левой границы полоски ХП. Последний цвет #Color 
    goto error_exit
end_if    
set logging Левый край полоски ХП цели найден в точке #xMobLeft #yMobHP Итераций: #i
set #xMobOver ( #xMobLeft + #overhit )

// Ищем правый край полоски хп
set #xMobRight #xMobLeft
set #x #xMobRight

// Быстрый поиск правой границы
set #diff 512
while #diff > 1
    set #diff ( #diff / 2 )            // Точность на этом шаге
    get color #Color #x #yMobHP
    if #Color = #ColorAlive or #Color = #ColorAlive2
        set #x ( #x + #diff )
        set logging Правую границу полоски ХП надо правее на #diff в точку #x
    else
        set #x ( #x - #diff )
        set logging Правую границу полоски ХП надо левее на #diff в точку #x
    end_if
    get color #Color #x #yMobHP
//    set logging Будем проверять цвет #Color в точке #x #yMobHP ?
//    move #x #yMobHP
end_while
set #xMobRight #x

// Проверка наличия полоски МП ниже полоски ХП
set #yMobMP (#yMobHP + 8)                       //  Абсолютный Y полоски МП цели
get color #Color #xMobLeft #yMobMP
//move #xMobLeft #yMobMP
// wait 4s
if_not #Color = #ColorMP
    set logging Вместо цвета маны #ColorMP в начале полоски МП найден #Color 
    goto error_exit
end_if
set logging Найдена полоска МП, скорее всего таргет действительно на себе

// Проверка стабильности правой границы
set #x ( #xMobRight +1)
wait 7777
get color #Color #x #yMobHP
//move #x #yMobHP
if #Color = #ColorAlive or #Color = #ColorAlive2
    set logging ХП не полное? Правее правой границы полоски ХП цвет оказался #Color 
    goto error_exit
end_if
// wait 2s

set #xMobHigh ( #xMobRight - 2 )
set logging Правый край полной полоски ХП цели найден в точке #xMobRight #yMobHP

send escape // снимаем таргет

return


///////////////////////////////////////////////////
// Проверка признака команды завершения - свернутого окна таргета
:check_close_exit
set $target findimage (0 0 111 222 (FindImage\L2\LTarget.bmp) %Target 2 90 1)
if $target > 90 // Окошко таргета закрыто
    set logging Окошко таргета свёрнуто - прекращаю работу
    goto error_exit
end_if
return         // Свёрнутого окна не найдено - продолжаем работу

///////////////////////////////////////////////////
// Процедура аварийного завершения скрипта
:error_exit
        set logging open         // открываем окошко с логами
    for #i 1 3
        alarm
//        wait 1s
    end_for
end_script

Пример Main Assister с якорем

Якорь:
БД стоит в центре комнаты, в перерывах между танцами иногда выполняет

/target %self
/targetnext

МА:
Макрос выбора ближнего моба:
/target БД
/assist

Макрос выбора дальнего моба:
/target Моб

Пример Damage Dealer с дебафом по ассисту MA

МА:
Дает таргет на нового моба, после смерти на следующего

DD:
Скрипт анализирует полоски хп, поэтому они должны быть видны. Если ДД на компе несколько, можно использовать просто кликер макроса /target MA /assist /attack.

Макрос выбора ближнего моба:
/target MA
/assist

Макрос выбора дальнего моба:
/target MA2
/assist

Макрос начала атаки:
/useskill debaf1
/useskill debaf2