Картинка ярлычка = нажатие кнопки, Нажатие разных кнопок в зависимости от всплывшего ярлычка Опции

[bumer]

В общем то вот такой вопрос. Ест-ли возможность написать в UO Pilot скрипт прожимающий разные кнопки (123...89) в зависимости от разных картинок ярлыков автоматически?
Если да, то может где-то тут на форуме кто нибудь уже решал такую задачку, я почему-то не нашёл. ткните пожалуйста носом.
Если озадачится решением такого вопроса на что стоит обратить внимание и будет ли это работать достаточно быстро?

[cirus]

Примерно так:

код

Код

set %image [1] image1           // имена картинок
set %image [2] image2
set %image [3] image3
set $path "C:\UOPilot\images\"    // путь к картинкам
init_arr %knopka 1 2 3               // кнопки, первая кнопка для первой картинки, вторая для второй и т .д.
set #flag 0

for #i 1 size(%image)             // поиск картинок циклом
    set #a findimage(0 0 1920 1080 ($path%image[#i].bmp) %arr)
    if  #a > 0                   // если картинка найдена
        set #flag 1
        break                    // прервать поиск
    end_if
end_for
if #flag = 1
    hint #i   %image [#i]             // номер и имя картинки
    send %knopka [#i]                // нажать кнопку
end_if
end_script

Можно не прерывать цикл поиска и делать нажатие внутри if. Тут уже зависит от дальнейших действий.
На счёт скорости, зависит от размера области поиска и размера искомой картинки. В среднем от 30 до 100 мсек на поиск одной картинки.
Если нужно быстрее, то в бета версии есть это:
https://forum.uokit.com/index.php?s=&sh...st&p=223715
https://forum.uokit.com/index.php?s=&sh...st&p=223888
https://forum.uokit.com/index.php?s=&sh...st&p=223896

[bumer]

О, это кажется то, что надо. Буду пробовать! (IMG:style_emoticons/default/rolleyes.gif)
Но вот хочется уточнить, можно ли как-либо ограничить область поиска в нужном окне, чтоб не весь экран анализировал, а только указанной области, где будут появляться интересующие мне всплывающие ярлычки-картинки? (IMG:style_emoticons/default/unsure.gif)
Поглядел ссылки и очень подозрительно похоже, на то о чем я спрашивал...

Код

        set %a GetImage  ( 100 100 1000 1000 )
        set #v %a [1 1]
        set $a findimage ( 51 51 1403 1403 (C:\test.bmp) %arr #v 80 1)
        set $b DeleteImage  ( %a [1 1] )

[cirus]

Но вот хочется уточнить, можно ли как-либо ограничить область поиска в нужном окне, чтоб не весь экран анализировал, а только указанной области, где будут появляться интересующие мне всплывающие ярлычки-картинки?

Координаты в Findimage это и есть область поиска. В GetImage также.

код2

Код

set %image [1] LoadImage(C:\image1.bmp)           // загрузка картинок в память
set %image [2] LoadImage(C:\image2.bmp)
set %image [3] LoadImage(C:\image3.bmp)
init_arr %knopka 1 2 3               // кнопки, первая кнопка для первой картинки, вторая для второй и т .д.

:metka
set %a GetImage  (200 200 700 700)        // сохранить скрин экрана в память
set #v %a [1 1]
for #i 1 size(%image)             // поиск картинок циклом
    set #a findimage(0 0 500 500 (%image[#i 1]) %arr #v)         // поиск картинок на сохранённом скрине
    if  #a > 0                   // если картинка найдена
        send %knopka [#i]                // нажать кнопку
    end_if
end_for
set $b DeleteImage  (%a [1 1])   // удалить скрин из памяти
goto metka

Этот вариант работает быстрее чем первый, актуален если много картинок, пока работает только в бета версии пилота.
Первый код чуть подправил.

[bumer]

Можно ли в место картинки использовать просто поиск цвета, но чтоб

Код

set #a findcolor (100 100 400 400 (color1 color2 color3) %arr) 

кликал по кнопкам так

Код

init_arr %knopka 1 2 3 

хочется чтоб получился очень короткий код, а необходимая кнопка жались при появлении картинки с нужными цветам. То есть не все кнопки разом, только та кнопка цвет которой будет обнаружен указанной области.

[cirus]

Код

init_arr %color (1)  color1 color2 color3     // цвета для первой картинки
init_arr %color (2)  color4 color5 color6     // второй
init_arr %color (3)  color7 color8 color9
init_arr %knopka 1 2 3
set delimiter ' '
for #i 1 size(%color)
    set #a findcolor (100 100 400 400 (%color [#i]) %arr)
    log Нашлось пикселей: #a
    if  #a > 0    // если при поиске картинки находится 20 пикселей, то
                  // вместо 0 указать хотя бы 10-15
        send %knopka [#i]
    end_if
end_for
end_script