Здравствуйте, гость ( Вход | Регистрация )

 
Ответить в эту темуОткрыть новую тему
> help me
UO новичок
сообщение 9.7.2018, 14:55
Сообщение #1


**

Neophyte
Сообщений: 28
Регистрация: 17.11.2017
Группа: Пользователи
Наличность: 0
Пользователь №: 18.687
Возраст: 30



Excuse me, I want to change the English to Chinese in the [admin]. I tried to convert the file encoding utf-8, but it is garbled in the game. Can someone help?

[DEFNAME admin_strings]
admin_clients_per_page 18
admin_plevel_0 "Guest"
admin_plevel_1 "Player"
admin_plevel_2 "Counselor"
admin_plevel_3 "Seer"
admin_plevel_4 "Game Master"
admin_plevel_5 "Developer"
admin_plevel_6 "Admin"
admin_plevel_7 "Owner"
admin_resdisp_0 "Pre-T2A"
admin_resdisp_1 "The 2nd Age"
admin_resdisp_2 "Lord Blackthorn's Revenge"
admin_resdisp_3 "Age Of Shadows"
admin_resdisp_4 "Samurai Empire"
admin_resdisp_5 "Mondain's Legacy"
admin_resdisp_6 "Kingdom Reborn"
admin_resdisp_7 "Stygian Abyss"


//< Function: Admin - Clients List >---------------------------------------------------->
//<------------------------------------------------------------------------------------->
[FUNCTION ADMIN]
IF (<GETREFTYPE>==<DEF.TREF_SERV>)
SERV.CONSOLE C
ELIF (<IsPLAYER>)
IF (<DEF0.admin_clients_per_page>)
DIALOGCLOSE d_sphereadmin
DIALOG d_sphereadmin
ELSE
SERV.LOG @Script Error: Wrong define for 'admin_clients_per_page', minimum value is 1.
SRC.SYSMESSAGE @026, Script Error: Wrong define for 'admin_clients_per_page', minimum value is 1.
ENDIF
ENDIF
RETURN


//< Dialog: Admin - Clients List >------------------------------------------------------>
//<------------------------------------------------------------------------------------->
[DIALOG d_sphereadmin]
50,50
page 0
resizepic 0 0 2620 700 38
resizepic 0 28 2620 700 378
resizepic 0 398 2620 700 35
button 665 7 4017 4019 1 0 0 // Cancel and close
dhtmlgump 200 8 465 20 0 0 <DEF.CENTER><DEF.BIG><DEF.BFONT_WHITE>Admin Control Panel
LOCAL.PAGE = 1+<SRC.CTAG0.admin_LastPage>
LOCAL.FROM = (<dLOCAL.PAGE> * <DEF0.admin_clients_per_page>) - <DEF0.admin_clients_per_page>
LOCAL.PAGES = (<SERV.CLIENTS>+<DEF0.admin_clients_per_page>-1) / <dDEF0.admin_clients_per_page>
LOCAL.LAST = (<dLOCAL.FROM> + <DEF0.admin_clients_per_page>)-1
LOCAL.LAST = <QVAL (<SERV.CLIENTS> <= <dLOCAL.LAST>)?<SERV.CLIENTS>-1:<dLOCAL.LAST>>
dhtmlgump 150 406 420 20 0 0 <DEF.CENTER><DEF.BIG><DEF.BFONT_WHITE>Clients online is: <SERV.CLIENTS>, showing <dDEF0.admin_clients_per_page> clients per page.
button 5 7 4014 4016 1 0 1
dhtmlgump 35 8 135 20 0 0 <DEF.CENTER><DEF.BIG><DEF.BFONT_WHITE>Page: <dLOCAL.PAGE>/<dLOCAL.PAGES>
button 170 7 4005 4007 1 0 2
dhtmlgump 40 40 135 20 0 0 <DEF.BIG><DEF.BFONT_WHITE><DEF.CENTER>Character
dhtmlgump 180 40 135 20 0 0 <DEF.BIG><DEF.BFONT_WHITE><DEF.CENTER>Account
dhtmlgump 320 40 115 20 0 0 <DEF.BIG><DEF.BFONT_WHITE><DEF.CENTER>IP
dhtmlgump 440 40 135 20 0 0 <DEF.BIG><DEF.BFONT_WHITE><DEF.CENTER>Location
dhtmlgump 580 40 110 20 0 0 <DEF.BIG><DEF.BFONT_WHITE><DEF.CENTER>PLevel
page 1
LOCAL.NAMES = "<DEF.BIG>"
LOCAL.ACCOUNTS = "<DEF.BIG>"
LOCAL.LASTIPS = "<DEF.BIG><DEF.CENTER>"
LOCAL.POSITIONS = "<DEF.BIG><DEF.CENTER>"
LOCAL.PLEVELS = "<DEF.BIG><DEF.CENTER>"
FOR <dLOCAL.FROM> <dLOCAL.LAST>
LOCAL.INDEX += 1
IF (<SERV.CLIENT.<dLOCAL._FOR>>)
DOSWITCH <SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT.PLEVEL>
LOCAL.Color=<DEF.BFONT_DGRAY> // Plevel: Guest Color: DkGray
LOCAL.Color=<DEF.BFONT_GRAY> // Plevel: Player Color: Gray
LOCAL.Color=<DEF.BFONT_ORANGE> // Plevel: Counselor Color: Orange
LOCAL.Color=<DEF.BFONT_DPURPLE> // Plevel: Seer Color: Violet
LOCAL.Color=<DEF.BFONT_RED> // Plevel: GM Color: Red
LOCAL.Color=<DEF.BFONT_BLUE> // Plevel: Developer Color: Blue
LOCAL.Color=<DEF.BFONT_YELLOW> // Plevel: Administrator Color: Yellow
LOCAL.Color=<DEF.BFONT_GREEN> // Plevel: Owner Color: Green
ENDDO
button 15 <EVAL 44+(<dLOCAL.INDEX>*18)> 2118 2117 1 0 <EVAL (1001 + <LOCAL._FOR>)>
LOCAL.NAMES = "<LOCAL.NAMES><LOCAL.Color><SERV.CLIENT.<dLOCAL._FOR>.NAME><DEF.BR>"
LOCAL.ACCOUNTS = "<LOCAL.ACCOUNTS><LOCAL.Color><SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT><DEF.BR>"
LOCAL.LASTIPS = "<LOCAL.LASTIPS><LOCAL.Color><SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT.LASTIP><DEF.BR>"
LOCAL.POSITIONS = "<LOCAL.POSITIONS><LOCAL.Color><SERV.CLIENT.<dLOCAL._FOR>.P.X>,<SERV.CLIENT.<dLOCAL._FOR>.P.Y>,<SERV.CLIENT.<dLOCAL._FOR>.P.Z>,<SERV.CLIENT.<dLOCAL._FOR>.P.M><DEF.BR>"
LOCAL.PLEVELS = "<LOCAL.PLEVELS><LOCAL.Color><DEF0.admin_plevel_<SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT.PLEVEL>><DEF.BR>"
ELSE
LOCAL.Color=<DEF.BFONT_DGRAY> // Client login in... Color: DkGray
LOCAL.NAMES = "<LOCAL.NAMES><LOCAL.Color>Login In...<DEF.BR>"
LOCAL.ACCOUNTS = "<LOCAL.ACCOUNTS><LOCAL.Color><SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT.NAME><DEF.BR>"
LOCAL.LASTIPS = "<LOCAL.LASTIPS><LOCAL.Color><SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT.LASTIP><DEF.BR>"
LOCAL.POSITIONS = "<LOCAL.POSITIONS><LOCAL.Color>-<DEF.BR>"
LOCAL.PLEVELS = "<LOCAL.PLEVELS><LOCAL.Color><DEF0.admin_plevel_<SERV.CLIENT.<dLOCAL._FOR>.ACCOUNT.PLEVEL>><DEF.BR>"
ENDIF
ENDFOR
dhtmlgump 40 60 135 340 0 0 <LOCAL.NAMES>
dhtmlgump 180 60 135 340 0 0 <LOCAL.ACCOUNTS>
dhtmlgump 320 60 115 340 0 0 <LOCAL.LASTIPS>
dhtmlgump 440 60 135 340 0 0 <LOCAL.POSITIONS>
dhtmlgump 580 60 110 340 0 0 <LOCAL.PLEVELS>

[DIALOG d_sphereadmin BUTTON]
ON=0 // Cancel/Close button
SRC.CTAG.admin_LastPage=
ON=1 // Back button
LOCAL.Pages = (<SERV.CLIENTS>+<DEF0.admin_clients_per_page>-1) / <dDEF0.admin_clients_per_page>
SRC.CTAG.admin_LastPage = <QVAL (<SRC.CTAG0.admin_LastPage>)?<SRC.CTAG.admin_LastPage>-1:<LOCAL.Pages>-1>
DIALOG d_sphereadmin
ON=2 // Forward button
LOCAL.Pages = (<SERV.CLIENTS>+<DEF0.admin_clients_per_page>-1) / <dDEF0.admin_clients_per_page>
SRC.CTAG.admin_LastPage = <SRC.CTAG0.admin_LastPage> + 1
SRC.CTAG.admin_LastPage = <QVAL (<SRC.CTAG0.admin_LastPage> < <LOCAL.Pages>)?<SRC.CTAG0.admin_LastPage>:0>
DIALOG d_sphereadmin
ON=1001,65535 // Clients tweak button
SRC.DIALOGCLOSE d_sphereadmin_tweak
TRY UID.<SERV.CLIENT.<EVAL (<ARGN>-1001)>.UID>.DIALOG d_sphereadmin_tweak


//< Dialog: Tweaking - Client >--------------------------------------------------------->
//<------------------------------------------------------------------------------------->
[DIALOG d_sphereadmin_tweak]
50,50
page 0
resizepic 0 0 2620 700 38
resizepic 0 28 2620 200 405
resizepic 195 28 2620 505 405
dhtmlgump 85 8 540 20 0 0 <DEF.CENTER><DEF.BIG><DEF.BFONT_WHITE>Admin Control Panel: Tweaking Client - <NAME>
button 665 7 4017 4019 1 0 0 // Cancel and close
button 5 7 4008 4010 1 0 1 // Back to clients list.
// Left menu actions
button 15 43 4005 4007 0 1 0
dtext 52 43 0480 Client information
button 15 63 4005 4007 0 0 0
dtext 52 63 0480 Client notes
button 15 83 4005 4007 1 0 2
dtext 52 83 0480 Character Info
button 15 123 4005 4007 1 0 11
dtext 52 123 0480 Go to this player
button 15 143 4005 4007 1 0 12
dtext 52 143 0480 Turn invisible and
dtext 52 163 0480 go to this player
button 15 183 4005 4007 1 0 13
dtext 52 183 0480 Summon player
button 15 203 4005 4007 1 0 14
dtext 52 203 0480 Summon player in
dtext 52 223 0480 a cage
button 15 243 4005 4007 1 0 15
dtext 52 243 00c1 Follow this player
button 15 283 4005 4007 1 0 16
dtext 52 283 <QVAL (<FLAGS>&statf_dead)?0045:0027> <QVAL (<FLAGS>&statf_dead)?Resurrect:Kill> player
button 15 303 4005 4007 1 0 17
dtext 52 303 0480 <QVAL (<ACCOUNT.JAIL>) ? Forgive:Jail> player
button 15 343 4005 4007 1 0 18
dtext 52 343 0480 Disconnect a player
button 15 363 4005 4007 1 0 19
dtext 52 363 0025 Disconnect and ban
dtext 52 383 0025 player.
page 1
dtext 210 40 00c1 Account:
dtext 330 40 0480 <ACCOUNT.NAME>
dtext 550 40 00c1 Characters:
dtext 630 40 0480 <ACCOUNT.CHARS>/<ACCOUNT.MAXCHARS>
FOR 0 (<ACCOUNT.CHARS>-1)
dtext 210 <EVAL 60+(<LOCAL._FOR>*20)> <QVAL (<UID>==<ACCOUNT.CHAR.<LOCAL._FOR>.UID>)?00c1:03e4> Character #<EVAL <LOCAL._FOR>+1>:
dtext 330 <EVAL 60+(<LOCAL._FOR>*20)> <QVAL (<UID>==<ACCOUNT.CHAR.<LOCAL._FOR>.UID>)?0480:03e4> <ACCOUNT.CHAR.<LOCAL._FOR>.NAME>
dtext 550 <EVAL 60+(<LOCAL._FOR>*20)> <QVAL (<UID>==<ACCOUNT.CHAR.<LOCAL._FOR>.UID>)?00c1:03e4> UID:
dtext 590 <EVAL 60+(<LOCAL._FOR>*20)> <QVAL (<UID>==<ACCOUNT.CHAR.<LOCAL._FOR>.UID>)?0480:03e4> <ACCOUNT.CHAR.<LOCAL._FOR>.UID>
ENDFOR
dtext 210 220 00c1 Language:
dtext 330 220 0480 <ACCOUNT.LANG>
dtext 210 240 00c1 Account Flags:
dtext 330 240 0480 <ACCOUNT.PRIV>
dtext 210 260 00c1 PLevel:
dtext 330 260 0480 <ACCOUNT.PLEVEL> (<DEF0.admin_plevel_<ACCOUNT.PLEVEL>>)
dtext 210 280 00c1 Client Version:
dtext 330 280 0480 <CLIENTVERSION> / <REPORTEDCLIVER>
dtext 210 300 00c1 Resdisp:
dtext 330 300 0480 <ACCOUNT.RESDISP> (<DEF0.admin_resdisp_<ACCOUNT.RESDISP>>)
dtext 210 340 00c1 First login:
dtext 330 340 0480 <ACCOUNT.FIRSTCONNECTDATE> from <QVAL ((<SRC.ACCOUNT.PLEVEL> <= <ACCOUNT.PLEVEL>) && (<SRC.ACCOUNT.PLEVEL> != 7) ? "x.x.x.x" : <ACCOUNT.FIRSTIP>>
dtext 210 360 00c1 Last login:
dtext 330 360 0480 <ACCOUNT.LASTCONNECTDATE> from <QVAL ((<SRC.ACCOUNT.PLEVEL> <= <ACCOUNT.PLEVEL>) && (<SRC.ACCOUNT.PLEVEL> != 7) ? "x.x.x.x" : <ACCOUNT.LASTIP>>
dtext 210 400 00c1 Time in game:
dtext 330 400 0480 <ACCOUNT.TOTALCONNECTTIME> minutes.

[DIALOG d_sphereadmin_tweak BUTTON]
ON=0
SRC.CTAG.admin_LastPage=
ON=1
SRC.DIALOGCLOSE d_sphereadmin
SRC.DIALOG d_sphereadmin
ON=2
DIALOG d_charprop1
ON=11
SRC.GO <P>
ON=12
SRC.INVIS 1
SRC.GO <P>
ON=13
GO <SRC.P>
ON=14
SUMMONCAGE
ON=15
IF (<SRC.UID>!=<UID>)
SRC.FOLLOW <UID>
ENDIF
ON=16
IF (<FLAGS>&statf_dead)
RESURRECT
ELSE
HITS=0
ENDIF
ON=17
IF (<ACCOUNT.JAIL>)
FORGIVE
ELSE
JAIL
ENDIF
ON=18
DISCONNECT
ON=19
KICK
Пользователь в офлайнеDelete PostОтправить личное сообщение
Вернуться в начало страницы
+Ответить с цитированием данного сообщения
Wap
сообщение 10.7.2018, 11:00
Сообщение #2


**********

Администратор Форума
Сообщений: 3.003
Регистрация: 22.12.2006
Группа: Администраторы
Наличность: 31646
Пользователь №: 9.227



SYSMESSAGE you should write
SYSMESSAGE @colorID,,1 TEXT
OR
SYSMESSAGE @,,1 TEXT
3rd argument = UNICODE.

About gumps I don't know, converting script file to UTF-8 should help.


--------------------
Пользователь в онлайне!Delete PostОтправить личное сообщение
Вернуться в начало страницы
+Ответить с цитированием данного сообщения
UO новичок
сообщение 12.7.2018, 16:50
Сообщение #3


**

Neophyte
Сообщений: 28
Регистрация: 17.11.2017
Группа: Пользователи
Наличность: 0
Пользователь №: 18.687
Возраст: 30



Цитата(Wap @ 10.7.2018, 11:00) *

SYSMESSAGE you should write
SYSMESSAGE @colorID,,1 TEXT
OR
SYSMESSAGE @,,1 TEXT
3rd argument = UNICODE.

About gumps I don't know, converting script file to UTF-8 should help.


I tried the conversion, but when I entered the game, the code was not displayed properly


Эскизы прикрепленных изображений
Прикрепленное изображение
Пользователь в офлайнеDelete PostОтправить личное сообщение
Вернуться в начало страницы
+Ответить с цитированием данного сообщения
Atheist
сообщение 12.7.2018, 22:58
Сообщение #4


********

Master
Сообщений: 1.272
Регистрация: 1.3.2006
Группа: Пользователи
Наличность: 0
Пользователь №: 5.330



Цитата(UO новичок @ 12.7.2018, 16:50) *

I tried the conversion, but when I entered the game, the code was not displayed properly

looks pretty chinese (IMG:style_emoticons/default/laugh.gif)


--------------------
0, 1, 1, 2, 3, 5, 8, 13, 21, 34, 55, 89, 144, 233, 377, 610, 987, 1597, 2584, 4181, 6765, 10946, 17711, 28657, 46368, 75025...
Пользователь в офлайнеDelete PostОтправить личное сообщение
Вернуться в начало страницы
+Ответить с цитированием данного сообщения

Ответить в эту темуОткрыть новую тему
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 

- Текстовая версия | Версия для КПК Сейчас: 29.3.2024, 0:36
Designed by Nickostyle