Поиск числа с помощью Findimage, Готовый скрипт Опции

[cirus]

Данный скрипт предназначен для распознавания чисел, текста и различных символов (например, значков серебра, голда).
Есть 2 версии скрипта: одна на языке пилота, вторая на языке lua.

Версия 1 (на языке пилота):

Минимальная версия пилота 2.39. Запускать от администратора.

Поиск числа с помощью Findimage 4.0 (на языке пилота)

Код

// Поиск числа с помощью FindImage
init_arr %GetImage (1) 0 0 245, 98      // координаты для поиска, StartX StartY EndX EndY

set linedelay 0
init_arr %picture 0 1 2 3 4 5 6 7 8 9     // имена картинок (0.bmp, 1.bmp и т. д.)
init_arr %symbol 0 1 2 3 4 5 6 7 8 9    // символ соответствующий имени, т. е. картинка 0.bmp соответствует 0
set $path "C:\Image3"                     // папка с картинками
set $bmp "*.bmp*"                           // формат картинок
set #deltaY 8                               // расстояние между строками (можно указать высоту картинок)
set #deltaspace 12                          // допустимое расстояние между цифрами, иначе будет считаться что это не одно число
set #accuracy 90                            // точность поиска для Findimage
set #deviation 3                            // погрешность оттенка  для Findimage
set #wait 2                                 // пауза между поиском картинок, если указать меньше искать будет быстрее, но нагрузит процессор
set #timeproc 2000                          // время (в мсек) для поиска картинок, если 0 не выйдет из процедуры пока не найдётся хотя бы 1 картинка
set #repeatimage 2                          // допустимое смещение координат, если используется несколько видов одной картинки

dir (%path $path $bmp)
set delimiter '   '
while 1 = 1
    set size(%result)                        // уничтожить массив с предыдущими результатами
    set size(%coord)                         // уничтожить массив с предыдущими координатами
    call test %picture %symbol %GetImage %path #deltaY #deltaspace #accuracy #deviation #wait #timeproc #repeatimage    // процедура поиска
//     save_array %result C:\Users\abc\Desktop\result111.txt     // массив с результатами поиска
//     save_array %coord C:\Users\abc\Desktop\coord111.txt     // массив с координатами чисел
    if  size(%result) > 0         // если размер массива больше 0
        // ТУТ НУЖНЫЕ ДЕЙСТВИЯ
        ///////////// для примера вывод в hint того что нашлось (можно убрать)
        set $str
        set %z [1] \n
        for #i 1 size(%result)
            set $str $str%result[#i]
            if  #i != size(%result)
                set $str $str%z [1]
            end_if
        end_for
        hint (14 clBlue 409, 265 ($str))
        /////////////
    else
        hint Картинки не найдены
    end_if
end_while

// процедура поиска и сортировки
proc test %picture %symbol %GetImage %path #deltaY #deltaspace #accuracy #deviation #wait #timeproc #repeatimage
    set #GetStartX %GetImage [1 1]
    set #GetStartY %GetImage [1 2]
    set #GetEndX %GetImage [1 3]
    set #GetEndY %GetImage [1 4]
    set #current_script current_script
    // загрузка картинок в память
    if  size(%path) > 0                  // если картинки найдены
        for #i 1 size(%path)
            for #j 1 size(%picture)
                if  %path [#i 3] = %picture [#j]
                    set #n #n + 1
                    set %image [#n] LoadImage(%path [#i 1])
                    set %number [#n] %symbol [#j]
                    break
                end_if
            end_for
        end_for
    else
        log Картинки в: $path   не найдены
        log Скрипт остановлен
        stop_script #current_script
    end_if
    // поиск картинок и их сортировка
    set size(%result1)
    set size(%coord_tmp)
    while size(%result1) = 0 and (#timeproc > timer or #timeproc = 0)
        set #z 0
        set %get GetImage(#GetStartX #GetStartY #GetEndX #GetEndY)      // сохранить часть экрана в память
        set #v %get [1 1]
        for #i 1 size(%number)
            set #a Findimage(0 0 %get [1 2] %get [1 3] (%image[#i 1]) %a #v #accuracy -1 #deviation)   // поиск
            if  #a < 0
                log Ошибка поиска картинки. Код ошибки: #a
                log Скрипт остановлен
                stop_script #current_script
            end_if
            if  #a > 0
                for #j 1 size(%a)
                    set #z #z + 1
                    init_arr %result1 (1 1 #z) %number[#i] %a[#j 1] %a[#j 2]   // запись результатов поиска в массив
                end_for
            end_if
            wait #wait
        end_for
        if  size(%result1) > 0
            gosub sortY        // сортировка по Y и X
        end_if
        set $b DeleteImage(%get[1 1])    // удалить изображение, полученное GetImage
    end_while
    goto end                 // выйти из процедуры

    :sortY
    ///// удаление повторных координат, если используется несколько видов одной картинки
        set #size 0
        set %tmp %result1
        set size(%result1)
        for #i 1 size(%tmp[1])
            set #break 0
            for #n 1 #size
                set #xrepeat %tmp[2 #i] - %result1[2 #n]
                set #yrepeat %tmp[3 #i] - %result1[3 #n]
                if  abs(#xrepeat) <= #repeatimage and abs(#yrepeat) <= #repeatimage
                    set #break 1
                    break
                end_if
            end_for
            if  #break = 0
                set #size #size + 1
                init_arr %result1 (1 1 #size) %tmp [1 #i]  %tmp [2 #i] %tmp [3 #i]
            end_if
        end_for
     ///////

        set #z 0
        set #z1 0
        set #z2 1
        set #z4 0
        sort_array %result1 -3
        while 1 = 1
            set #z 0
            set size(%tmp)
            for #i #z2 eval(size(%result1 [1]) - 1)
                set #j #i + 1
                set #x %result1 [3 #i] - %result1 [3 #j]
                if  abs(#x) < #deltaY
                    set #z #z + 1
                    init_arr %tmp (1 1 #z) %result1 [1 #i]  %result1 [2 #i] %result1 [3 #i]
                else
                    set #z #z + 1
                    init_arr %tmp (1 1 #z) %result1 [1 #i]  %result1 [2 #i] %result1 [3 #i]
                    break
                end_if
            end_for
            set #z2 #z2 + #z
            if  #z2 = size(%result1[])
                set #x %result1 [3 #i] - %result1 [3 #j]
                if  abs(#x) > #deltaY
                    set #jj #j
                    sort_array %tmp -2
                    set #z1 #z1 + 1
                    init_arr %result (#z1) %tmp [1]
                    set %coord_tmp [#z1] %tmp [2 1], %tmp [3 1]
                    set %coord.#current_script [#z1] %tmp [2 #z], %tmp [3 #z]
                    gosub space
                    set size(%tmp)
                    set #z #z + 1
                    init_arr %tmp (1 1 #z) %result1 [1 #jj]  %result1 [2 #jj] %result1 [3 #jj]
                    set #z1 #z1 + 1
                    set %result.#current_script [#z1] %tmp [1]
                    set %coord.#current_script [#z1] %tmp [2 #z], %tmp [3 #z]
                    gosub end
                end_if
                set #z #z + 1
                init_arr %tmp (1 1 #z) %result1 [1 #j]  %result1 [2 #j] %result1 [3 #j]
                sort_array %tmp -2
                set #z1 #z1 + 1
                init_arr %result (#z1) %tmp [1]
                set %coord_tmp [#z1] %tmp [2 1], %tmp [3 1]
                gosub space
                break
            else
                sort_array %tmp -2
                set #z1 #z1 + 1
                init_arr %result (#z1) %tmp [1]
                set %coord_tmp [#z1] %tmp [2 1], %tmp [3 1]
                gosub space
            end_if
        end_while
    return

    :space
        set #z3 0
        set size(%space)
        set #z4 #z4 + 1
        //посчитать где нужны пробелы
        for #i 1 eval(size(%tmp[]) - 1)
            set #j #i + 1
            set #space  %tmp [2 #i] - %tmp [2 #j]
            if  abs(#space) > #deltaspace
                set #z3 #z3 + 1
                set %space[#z3] #j
                set #size_coord 1
                while %coord_tmp[#z1 #size_coord] != ""
                    set #size_coord #size_coord + 1
                end_while
                set %coord_tmp [#z1 #size_coord] %tmp [2 #j], %tmp [3 #j]
            end_if
        end_for
        // вставить пробелы
        for #i 1 size(%space)
            set $str %result [#z4]
            set $str insert(" " $str %space[#i])
            set #j #i + 1
            set %space[#j] %space[#j] + #i
            set %result [#z4] $str
        end_for
        // сохранение массива в основном скрипте
        for #i 1 size(%result)
            set size(%tmp1)
            init_arr %tmp1 (1) %result [#i]
            for #j 1 size(%tmp1[1])
                set %result.#current_script [#i #j] %tmp1 [1 #j]
                set %coord.#current_script [#i #j] %coord_tmp [#i #j]
            end_for
        end_for
    return

    :end
end_proc

Результат поиска

Код

%result [1 1] - первая строка, первое число    %coord [1 1] - координаты числа
%result [1 2] - первая строка, второе число    %coord [1 2] - координаты числа
%result [2 1] - вторая строка, первое число    %coord [2 1] - координаты числа

Видео работы скрипта

https://youtu.be/pxPEjszKvK4

Версия 2 (на языке lua):

Функция

 FindString.lua ( 45,96 килобайт ) Кол-во скачиваний: 830

Мануал

Автор скрипта DarkMaster.
Вопросы, баги, предложения на форум
в специальную тему по этому скрипту
https://forum.uokit.com/index.php?showtopic=30000

Мануал по использованию:

Данный скрипт предназначен для распознавания чисел,
текста и различных символов (например, значков серебра, голда).
Скрипт учитывает возможные пробелы и переносы строк.
Параметры в квадратных [] скобках являются не обязательными,
параметры в угловых скобках <> указываются всегда.
Квадратные и фигурные скобки при вызове функций не пишутся,
они лишь указывают на возможность не задавать параметр.
Фигурные {} и круглые () скобки пишутся там, где указаны.
Символ '|' означает исключающее или, например, sub=0|1 означает,
что значение sub может быть равно либо 0, либо 1.

Для удобства использования необходимо
сохранить скрипт в отдельный файл
и подгружать в начале вашего скрипта:
imageToString = require("luaPlugins\\FindString")
Вызов данной команды загрузит модуль
FindString.lua из папки luaPlugins,
расположенной рядом с пилотом.
Т.е. "luaPlugins\FindString.lua"


Скрипт включает в себя следующие функции:

Управление буфером:
Добавление изображения в буфер (вернет адрес):
imageToString.bufferAdd(<путь>,

Получение адреса в памяти загруженного в буфер изображения:
imageToString.bufferGet(<путь>)[адрес])

Удаление изображения из буфера:
imageToString.bufferDelete(<путь>)

Полная очистка буфера:
imageToString.bufferFlush()


Получение текста из изображения:
t = imageToString.get{[parms],[parms],[parms],...}
Внимание! Скобки фигурные!
Указывается либо папка либо набор символов!
[loadFolder] | [[symbols],[path],[ext]]

Полный синтаксис:
t = imageToString.get{

Параметр(все необязательные) Значение по умолчанию
window=<хендл|метод> -- workwindow()
loadFolder={<path="путь">, [mask="маска"], [sub=0|1]} -- nil
symbols={"0", "1", ["2"] = {"two", "second"}, "3"} -- {["1"]={"1"}, ["2"]={"2"}, ["3"]={"3"}, ["4"]={"4"}, ["5"]={"5"},
-- ["6"]={"6"}, ["7"]={"7"}, ["8"]={"8"}, ["9"]={"9"}, ["0"]={"0"}}
path=<"путь"> -- "images\\"
ext=<"расширение"> -- "*.bmp"
crds={<xStart>, <yStart>, <xEnd>, <yEnd>, [abs=0|1]} -- размер окна (workwindow(), если окно явно не указано), если не задано - рабочего стола.
accuracy=<число> -- 95
deviation=<число> -- 2
deltaSpace=<число> -- 2
deltaY=<число> -- 8
dupImage=<число> -- 3
toNumber=<0|1> -- 1
source={<address>, <width>, <height>} -- nil
saveImage=<"путь"> -- nil
wait=<число> -- 2
durationMax=<число> -- 0
secondFrame=<число> -- 0
bufferAddNew=<0|1> -- 1
bufferUpdate=<0|1> -- 0
bufferIgnore=<0|1> -- 0
}


Результат при поиске текста:

t = imageToString.get{[parms],[parms],[parms],...}
Функция возвращает двумерную таблицу,
где первый индекс является номером строки,
второй номером слова.
Если ничего не найдет, вернет nil.
Например, при распознавании текста:

Съешь еще
этих
мягких французских булок.

Массив будет содержать следующие значения:
t[1][1] -- Съешь
t[1][2] -- еще
t[2][1] -- этих
t[3][1] -- мягких
t[3][2] -- французских
t[3][3] -- булок


Параметры при поиске текста:

Данный оператор имеет большое количество возможных параметров,
все они являются необязательными.
В теле скрипта есть блок значений
параметров, используемых по умолчанию,
которые вы при желании можете изменить (таблица default).

window=<хендл|метод>
Хендл окна в котором происходит поиск либо метод 1|2.
Поиск в перекрытых окнах происходит только при указании хендла.
При указании хендла для корректного считывания изображения может
понадобиться указывать хендл родительского окна.
Значение по умолчанию: workwindow().

loadFolder={<path="путь">, [mask="маска"], [sub=0|1]}
Загрузка всех изображений из указанной папки.
Имена файлов должны соответствовать символу
который они означают (расширение не учитывается).
Допускаются файлы с одинаковым именем в разных папках.
<path="путь"> - абсолютный путь по которому находится папка.
Для преобразования относительного пути в абсолютный можно
использовать конструкцию: path=homepath() .. "относительный путь".
[mask="маска"] - маска по которой будут загружены файлы.
Допускается использование символов '?' и '*'.
? - означает один любой символ,
* - любое количество неизвестных символов.
Обратите внимание, что mask=".bmp" означает
точное совпадение полного имени файла с указанной маской,
т.к. символы подстановки не использованы.
Если же указать mask="*.bmp",
то будут загружены все файлы, заканчивающиеся сочетанием ".bmp".
Значение по умолчанию: "*.bmp".
[sub=0|1] - флаг, указывающий на загрузку изображений,
в том числе из подпапок.
При указании loadFolder будут проигнорированы параметры:
symbols, path, ext.
Значение по умолчанию: nil.

symbols={}
Символы для поиска.
Набор символов возможно указать в двух вариантах синтаксиса:
упрощенном и полном.
Упрощенный вариант синтаксиса допускает не указывать
соответствие имен файлов и строке/символу,
который они обозначают: считается, что они идентичны.
Пример упрощенного синтаксиса:
symbols = {"0", "1", "2", "3", "a", "b", "c", "test"}
Полный синтаксис бывает необходим при использовании нескольких
изображений, соответствующих одной и той же строке/символу.
Допускаются переносы строк:
symbols = {
["0"] = {"zero1", "zero2"},
["1"] = {"1a", "1b"},
["2"] = {"two", "second"}
}
Оба варианта синтаксиса можно сочетать:
symbols = {"0", "1", ["2"] = {"two", "second"}, "3"}
Данный параметр игнорируется,
если указана загрузка папки (loadFolder).
Значение по умолчанию:
{["1"]={"1"}, ["2"]={"2"}, ["3"]={"3"}, ["4"]={"4"}, ["5"]={"5"},
["6"]={"6"}, ["7"]={"7"}, ["8"]={"8"}, ["9"]={"9"}, ["0"]={"0"}}

path=<"путь">
Путь, по которому находятся изображения, указанные в symbols.
Путь может быть задан относительным или абсолютным.
Данный параметр игнорируется,
если указана загрузка папки (loadFolder).
Все символы '\' должны быть удвоены (escape-последовательность).
Пример:
path="c:\\image.bmp"
Если путь будет начинаться с символа '\',
то он будет восприниматься относительно корня диска.
Пример:
Если пилот находится по адресу d:\uopilot\uopilot.exe,
то параметр path="\\myFolder"
будет указывать на папку d:\myFolder.
Значение по умолчанию: "images\\".
Это относительный путь, указывающий на папку images,
которая находится рядом с .exe пилота (создается пользователем).

ext=<"расширение">
Расширение картинок, указанных в symbols.
Данный параметр игнорируется,
если указана загрузка папки (loadFolder).
Значение по умолчанию: ".bmp".

crds={<xStart>, <yStart>, <xEnd>, <yEnd>, [abs=0|1]}
Координаты, в которых необходимо производить поиск.
При указании флага abs=1 координаты будут считаться
относительно левого верхнего угла экрана,
в противном случае координаты рассчитываются
относительно левого верхнего угла приложения.
Значение по умолчанию:
размер окна с которым работает функция и относитльные координаты,
если окно не указано и привязка плиота отсутствует, то
используется разрешение рабочего стола и абсолютные координаты.

accuracy=<число>
Точность поиска изображений.
Для текста рекомендуется указывать 95-100.
Значение по умолчанию: 95.

deviation=<число>
Допустимое отклонение оттенка в процентах (255/100*deviation).
Если цвет 50 100 150, то при указании deviation=2
допустимыми значениями будут являться 44-55 94-105 144-155.
Дробная часть при вычислении диапазона
не округляется, а отбрасывается.
Значение по умолчанию: 2.

deltaSpace=<число>
Допустимое расстояние по горизонтали между изображениями.
Если значение превышено считается,
что началось новое слово (присутствует пробел).
Значение по умолчанию: 2.

deltaY=<число>
Смещение по высоте при превышении которого считается,
что символы принадлежат к разным строкам.
Значение по умолчанию: 5.

dupImage=<число>
Смещение, при котором два найденных изображения
будут считаться дубликатом одного.
Значение по умолчанию: 3.

symbolPrio={symbol_1, symbol_2, symbol_3, ...}
Устатнавливает приоритет удаления дублей.
Часть симоволов может содержаться в других символах.
Например при распозновании "Q" очень велика вероятность,
что будет надена буква Q и буква O, аналогично в парах:
7 и 1, 4 и 1 и т.д.
Приоритет определяется позицией символа в массиве,
чем меньше индекс, тем выше приоритет.
Например: {"q", "o", "7", "4", "1"}
заменит О на Q, 1 на 4, 4 на 7 и т.д.,
если они обнаружены в пределах области
считающейся дублями.
Для выключения использовать: {}
Значение по умолчанию: {"q", "o", "7", "4", "1"}

toNumber=<0|1>
Флаг, при котором слова, состоящие только из цифр
будут преобразованы из строки в числовой тип данных.
Это необходимо для арифметических действий, а также
для сравнения чисел.
Значение по умолчанию: 1.

source={<address>, <width>, <height>}
Источник загруженного в память изображения
в котором производить поиск.
<address> - адрес в памяти
<width> - ширина изображения
<height> - высота изображения
Изображение возможно загрузить в память при помощи
getimage() или loadimage().
Значение по умолчанию: nil.

saveImage=<"путь">
Путь, по которому будет сохранено изображение
в котором происходил поиск.
Значение по умолчанию: nil.

wait=<число>
Пауза в миллисекундах (1000мс=1сек) между поиском изображений.
Используется для снижения нагрузки на процессор
ценой увеличения времени поиска.
Значение по умолчанию: 2.

durationMax=<число>
Время в течении которого будут происходить
повторные попытки найти изображение.
Значение может быть дробным, например:
durationMax=2.5.
При указании durationMax=-1 поиск будет происходить
бесконечно до тех пор, пока изображение не будет найдено.
Если первое изображение было найдено,
то остальные будут обработаны полностью
вне зависимости от таймера,
т.е. вы не получите обрезанный текст.
При первом успешном распознавании текста функция завершит работу
и передаст результат, не дожидаясь окончания таймера.
Значение по умолчанию: 0.

secondFrame=<число>
Параметр позволяет задать паузу между
первым нахождением изображения и началом
считывания изображений для распознавания текста.
Позволяет дождаться полной прогрузки
текста перед обработкой.
Обратите внимание, что параметр durationMax учитывает значение
secondFrame и не позволит функции работать дольше,
чем указано в durationMax. Значение по умолчанию:0.

bufferAddNew=<0|1>
Флаг разрешающий добавлять в память буфера изображения,
которые отсутствовали в буфере и были считаны с диска.
Данный параметр игнорируется,
если указан bufferIgnore=1.
Значение по умолчанию: 1.

bufferUpdate=<0|1>
Флаг указывающий на то,
что изображения в буфере должны быть обновлены.
Они будут считаны с диска заново.
Обновятся только те изображения,
которые будут участвовать в поиске.
Данный параметр игнорируется, если указан bufferIgnore=1.
Значение по умолчанию: 0.

bufferIgnore=<0|1>
Флаг, запрещающий работать с буфером.
Данный из буфера считаны не будут,
загрузка искомых изображений произойдет с диска.
Никаких данных в буфер не сохраняется.
Значение по умолчанию: 0.


Пример вызова:
local cell = fs.get{
loadFolder = {path = "image\\comeback", mask="*"},
crds ={x*254, y*36, 108+x*254, 17+y*36},
deltaSpace = 10
}

Если в области для распознования содержатся посторонние данные,
то может быть полезено вызвать функцию несколько раз с областями
непосредственно содержащими данные.
Пример функции для сбора значений представленных в виде таблицы:
get_prices = function(offset_x, offset_y)
local img, w, h, l = getimage(offset_x, offset_y,
410+offset_x, 340+offset_y)
local price = {}
for x = 0, 1 do
for y = 0, 9 do
local cell = fs.get{
loadFolder = {path = "image\\comeback", mask="*"},
source = {img, w, h},
crds ={x*254, y*36, 108+x*254, 17+y*36},
deltaSpace = 10
}
if cell then
price[#price+1] = cell[1][1]
end
end
end
deleteimage(img)
return price
end

Changelog

История изменений:

1.0.9
Добавлено: установление приоритетов символов при удалении дублей. 4 и 1 - будет удалено 1, O и Q удалено O и т.д.
Добавлено: пример вызова, пример для сбора табличных данных.
Фикс: исправлены проблемы findimage пилота при поиске в уже загруженном изображении (getimage/loadimage)

1.0.8
Фикс: Убраны кавычки из пути при loadFolder. В связи с апдейтом пилота и фиксом функции dir этого более не требуется(приводит к битым путям).
Фикс: В связи с отправкой в мусорку crystalLua убраны костыли в виде доп параметра в управлении буфером. Приветствуем luajit!
Фикс: При одновременном использовании secondFrame и абсолютных координат область поиска предварительного обнаружения изображения могла быть искажена.
Фикс: В связи с правками в пилоте убран старый синтаксис передачи параметров в findimage стрингом. Теперь параметры передаются без дополнительных конвертаций и вынужденных глобальных переменных. Небольшое увеличение производительности.
Фикс: В связи с правками в пилоте убрано преобразование возвращаемых координат из строки в число. Небольшое увеличение производительности.
Фикс: В связи с правками в пилоте окно по умолчанию теперь задается функций workwindow(), а не строкой и не зарезервированной переменной.
Фикс: Исправлено описание функций. workwindow и homepath в пилоте теперь функции - workwindow() и homepath().
Добавлено: Значение по умолчанию теперь изменено с фиксированного 0, 0, 1919, 1079, abs=0 на динамическое: используется размер окна с которым идет работа(по умолчанию workwinodow()), если окно не указано и привязка пилота отсутствует, то используется разрешение рабочего стола и абсолютные координаты.
Изменено: значение по умолчанию deltaY с 8 до 5.
Рефакторинг: В связи с правками в пилоте убраны костыли для обхода бага с координатами поиска (начальные нельзя было задать отличные от нуля, после поиска происходил отсев). Небольшое повышение производительности.
Рефакторинг: В связи с правками в пилоте убрано добавление пробела перед флгом рекурсии при получении списка файлов для loadFolder. Переработана инициализация параметра. Синтаксис и результат не изменился.
Рефакторинг: переработана инициализация параметра symbols. Синтаксис и результат не изменился.
Рефакторинг: переработана инициализация параметра crds.abs. Синтаксис и результат не изменился.

1.0.7
Фикс: убрано принудительное преобразование строк в числа - игнорировалась опция toNumber=<0|1>.

1.0.6
Правки орфографии, пунктуации в описании.

1.0.5
Фикс: убраны сообщения отладки в лог.
Добавлено: imageToString.buffer.add теперь возвращает адрес загруженного изображения.

1.0.4
Фикс: добавлен набор костылей для адекватной передачи параметров при вызове функций буфера.
Добавлено: опция toNumber для преобразования строк в числа.

1.0
Фикс: при передаче источника изображения (source) игнорировались координаты поиска.
Изменено: timeProc переименован в durationMax.
Изменено: глобальная переменная, которую необходимо использовать из-за проблем финдимиджа переименована из tmp в tmpOtNiAotNiaorNCOsnaOT.

Фикс: загрузка файлов из папки теперь различает папки и файлы и больше не пытается загрузить папку, как изображение.
Изменено: конечные координаты области поиска равняются (ширина - 1) и (высота - 1) от забранного изображения. (отсчет с нуля)

Фикс: имена функций буфера.
Добавлено: возможность помещать в буфер изображения с диска.
Добавлено: возможность считать адрес в памяти буферизированного изображения.
Изменено: параметр abs теперь задается внутри crds{}

Фикс: символы по умолчанию больше не переписываются, сделано корректное копирование массива.

Фикс: флаг чтения подпапок был инвертирован.
Фикс: secondFrameTimeout больше не глобальная и используется по назначению.
Фикс: При default.durationMax = -1 и default.secondFrame > 0 не выходит преждевременно из функции.
Фикс: Почистил отладочные выводы в лог.
Добавлено: сохранение изображение в котором происходил поиск.

Баг: из-за особенностей костыля финдимиджа создается НЕ локальная переменная tmp.
Фикс: изображение не добавлялось в буфер.
Фикс: расчет пробела от конечной х координаты.
Фикс: очистка буфера после захвата изображения.
Фикс: область поиска при источнике из getimage должна быть с нуля.
Фикс: искалось только одно изображение из-за недостающего вложенного цикла.
Фикс: буфер теперь действительно буферизует.
Переработано преобразование из упрощенного синтаксиса в полноценный. Добавлена защита от дурака (типы данных).
Добавлено: загрузка папки с изображениями.
Добавлено: ожидание прогрузки изображений (options.secondFrame).
Добавлено: чтение из буфера.

Сообщение отредактировал DarkMaster - 24.11.2022, 9:00

[WKnight]

Исправил в 'findimage' поиск запомненной картинки в загруженной области.

Это откатил до десятой беты. Доступно в нестабильной сборке http://uopilot.uokit.com/dld.php

[cirus]

Доступно в нестабильной сборке http://uopilot.uokit.com/dld.php

Что-то не то выложил. Размер 22 байта.

[WKnight]

Пасиб, починил.

[Alex83]

доброго времени, попробовал как работает на этом примере, но что то не оч получилось не находит искомое, или я чтот не так делаю, в этом месте (C:\мойкомпьютер.bmp) должна находится картинка или нет и обязательно ли писать .bmp, после того что хотим найти
// Пример 6
//Чтобы понять как работает поиск можно попробовать на рабочем столе найти значок 'Мой компьютер'.
//Делаем картинку значка в формате bmp, называем 'мойкомпьютер' (без кавычек), закидываем на диск 'C:'.
//При этом можно перекрыть значок каким-нибудь окном.

//Не забываем сделать привязку Ctrl + A.
set #a FindImage(0 0 1920 1080 (C:\мойкомпьютер.bmp) %arr workwindow)
if #a > 0
log Картинка найдена. Наведём на неё курсор.
move %arr [1 1] %arr [1 2]
End_script
else
msg Картинка не найдена.
end_if

[cirus]

Давайте не будем засорять тему вопросами, которые не имеют отношения к данному скрипту.
Лучше создать отдельную тему.

[Alex83]

Что-то не то выложил. Размер 22 байта.

доброго времени, подскажите пож для данного скрипта что бы он распознал комбинацию цифер, допустим нужно найти число 46, для этого нужно делать 2 картинки с цифрами 4 и 6 или сразу 46 одной картинкой, заранее спс.

[cirus]

допустим нужно найти число 46, для этого нужно делать 2 картинки с цифрами 4 и 6 или сразу 46 одной картинкой, заранее спс.

Если всегда надо искать число 46, то можно одну картинку. Тогда не потребуется этот скрипт.
Если нужно искать разные числа, то надо делать картинки всех цифр.

[DarkMaster]

Собственно совсем забылось. Прикрепи в первый пост, тему помню ты хотел почистить, если есть желание.

[cirus]

Прикрепи в первый пост

Прикрепил. Потом добавлю примеры вызова.

тему помню ты хотел почистить, если есть желание

Изначально я предлагал сделать отдельную тему, чтоб эту не чистить (IMG:style_emoticons/default/smile.gif)
Почищу как время будет. Я так понимаю права нужны.

[FREEON]

Как с помощью данного скрипта вывести значения картнок в таблицу из массива?

Есть стандартное поле с условно-рандомно генерируемых цифр разделенных сеткой
нужно записать значение по боксам
set %arr [ 1 1] число из 1 строки 1столбца
set %arr [ 1 2] число из 1 строки 2столбца
set %arr [ 1 3] число из 1 строки 3столбца
set %arr [ 1 4] число из 1 строки 4столбца
set %arr [ 2 1] число из 2 строки 1столбца
set %arr [ 2 2] число из 2 строки 2столбца
set %arr [ 2 3] число из 2 строки 3столбца
set %arr [ 2 4] число из 2 строки 4столбца
set %arr [ 3 1] число из 3 строки 1столбца
set %arr [ 3 2] число из 3 строки 2столбца
set %arr [ 3 3] число из 3 строки 3столбца
set %arr [ 3 4] число из 3 строки 4столбца
set %arr [ 4 1] число из 4 строки 1столбца
set %arr [ 4 2] число из 4 строки 2столбца
set %arr [ 4 3] число из 4 строки 3столбца
set %arr [ 4 4] число из 4 строки 4столбца
Нужно ли прописывать для каждой ячейки область поиска или можно сделать лишь задав одну, а найденные изображения(цифры) можно будет записать с лево на право и с верху вниз???

[DarkMaster]

Можно обойтись одной областью, но скрипт нужно обновить. У меня походу монитор накрылся... Не могу сделать это прямо сейчас...

[DarkMaster]

Скрипт из нестабильной версии. Вроде был рабочий =)

[FREEON]

Скрипт из нестабильной версии. Вроде был рабочий =)

где задаются координаты поиска? в коментарии есть строчка crds={<xStart>, <yStart>, <xEnd>, <yEnd>, [abs=0|1]} которая хадает облость поиска, но в рабочей части только есть эта строка default.crds = function(window) -- Координаты поиска.

При попытке запустить выдает ошибку версия нестабильная.
syntax error during precompilation. 95: invalid escape sequence near "t> ~lua
do
function table.show(data, comment)
правки которые делал в файле:

Код

 local default = {}
    default.window       = function() return workwindow() end   -- Метод|хендл_окна в котором происходит поиск (если указан источник изображения(source), то параметр будет проигнорирован).
    default.loadFolder   = nil      -- Путь, по которому будут загружены все изображения с указанной маской {path=путь, mask=маска, sub=1|0}(sub - подпапки). Имя файла будет соответсвовать имени символа.
                                            -- Набор стандартных символов.
    default.symbols      = {["0"]={"0"}, ["2"]={"2"}, ["4"]={"4"}, ["8"]={"8"}, ["16"]={"16"}, ["32"]={"32"}, ["64"]={"64"}, ["128"]={"128"}, ["256"]={"256"}}
    default.path         = "D:\_UOPilot\_2048"       -- Папка с картинками.
    default.ext          = ".bmp"           -- Расширение картинок.
    default.crds         = function(window) -- Координаты поиска.

ну и первый комент подчистил для уменьшения объема

[DarkMaster]

local default = {}

Это таблица умолчаний. Т.е. если не заданы какие-либо параметры, то они берутся отсюда. Это править можно, но нужно понимать, что это это едва ли то, что нужно делать первый раз увидев скрипт. Для начала сделайте обычный вызов функции. Картинки рекомендую подгружать через loadFolder.

[FREEON]

В общем понял, что ничего не понял...язык пилота мне понятнее.

Cirus что может быть запускаю скрипт на языке пилота доходит до строчки:

Код

call test %picture %symbol %GetImage %path #deltaY #deltaspace #accuracy #deviation #wait #timeproc #repeatimage    // процедура поиска

и далее ничего не происходит и не стопоритя и ошибок не выбивает и до вывода результата с if также не даходит. Включал слежку за строками он доходит до вызова процедуры(код строки выше) и все никуда больше не на выполнение процедуры не переходит и дальше на if тоже не переходит. Попробовал взять в скобки то что находится после test вроде как проскакивает на выполнение и потом назад... можэ что там смесь % и # данных (IMG:style_emoticons/default/ohmy.gif) .... Помоги разобраца (IMG:style_emoticons/default/mellow.gif)

[cirus]

Как с помощью данного скрипта вывести значения картнок в таблицу из массива?

Для этой задачи не нужен этот скрипт. Т. к. часть фишек могут отсутствовать, всё равно придётся играться с координатами, чтобы заполнить массив.
Допустим поле 4*4 размером 400*400, нашли картинку цифры 2 в координатах 120, 215. Значит цифру надо записать в arr[2][3]. Т. к. размеры клетки 100*100, то координаты от 0 до 100 это первая строка/столбец, 100-200 вторая и т. д.

[FREEON]

Для этой задачи не нужен этот скрипт. Т. к. часть фишек могут отсутствовать, всё равно придётся играться с координатами, чтобы заполнить массив.
Допустим поле 4*4 размером 400*400, нашли картинку цифры 2 в координатах 120, 215. Значит цифру надо записать в arr[2][3]. Т. к. размеры клетки 100*100, то координаты от 0 до 100 это первая строка/столбец, 100-200 вторая и т. д.

Ну с утра тоже думаю просто сделать по координатам, написать простой скрипт типа по точкам где присваются значения (состоящая из точек) и процедура где есть все значения от 0 до 2048. И ужэ условно производить по очереди перебор значений. Но пака есчо перевариваю как это лучше сворганить.

[FREEON]

Для этой задачи не нужен этот скрипт. Т. к. часть фишек могут отсутствовать, всё равно придётся играться с координатами, чтобы заполнить массив.

Если ты имеешь в виду пустые плитки то их значение делаем 0(т.е пустую плитку делаем картинку с именем 0.bmp). Если имеешь в виду к примеру большие числа 4 ... 512 1024 и 2048 то и буквы и цифры тоже не всегда появляется на экране, не думаю что это как-то критично. наша задача найти из того что есть и присвоить значения. Грубо говоря все в рамках есть картина состоящая из стандартных кусков(картинок) которые то появляются то передвигаются, других нестандартных кусков нет.

Допустим поле 4*4 размером 400*400, нашли картинку цифры 2 в координатах 120, 215. Значит цифру надо записать в arr[2][3]. Т. к. размеры клетки 100*100, то координаты от 0 до 100 это первая строка/столбец, 100-200 вторая и т. д.

Есть вопросы...не совсем понятно какой код нужен что бы связать поиск с присвоением значением массива?

Код

set linedelay 0
log clear
log mode compact
set $path "D:\_UOPilot\_2048" // папка с картинками
//init_arr %image 0 2 4 8 16 32 64 128 256 512 1024 2048    //имена картинок (0.bmp, 1.bmp и т.д.)
//init_arr %bukva 0 2 4 8 16 32 64 128 256 512 1024 2048   // цифра
set delimiter ' '
dir (%image $path *.bmp*)   // поиск картинок в папке и загрузка их в массив
log В папке найдено: size(%image) картинок
//дописать процесс поиска по облостям
for #i 1 size(%image)   // цикл для поиска картинок (дописать)
    set #x11 findimage( координаты 1.2  #startX #startY #endX #endY) поиск нужной? // область поиска ячейка 1- 1
    if  #x11 > 0 //если в ячейке 1 1 нашлась картинка присвоить значение
        set %arr [1 1] присвоить число картинки
    end_if
    set #x12 findimage( координаты 1.2  #startX #startY #endX #endY) поиск нужной? // область поиска ячейка 1- 2
    if  #x12 > 0 //если в ячейке 1 1 нашлась картинка присвоить значение
        set %arr [1 2] присвоить число картинки
    end_if
    //анологично для остальных
    set #x44 findimage( координаты 4.4  #startX #startY #endX #endY) поиск нужной? // область поиска ячейка 4- 4
    if  #x44 > 0 //если в ячейке 4 4 нашлась картинка присвоить значение
        set %arr [4 4] присвоить число картинки
    end_if
    //сделать проверку если все значение заданы перейти то выйти из цикла и перейти к поиску и просчету хода
    if все значения if> 0
        log %arr [1 1] %arr [1 2] и т.д
       Break
    end_if
end_for
end_script

или

Код

set linedelay 0
log clear
log mode compact
set $path "D:\_UOPilot\_2048" // папка с картинками
//init_arr %image 0 2 4 8 16 32 64 128 256 512 1024 2048    //имена картинок (0.bmp, 1.bmp и т.д.)
//init_arr %bukva 0 2 4 8 16 32 64 128 256 512 1024 2048    // цифра
set delimiter ' '
dir (%image $path *.bmp*)   // поиск картинок в папке и загрузка их в массив
log В папке найдено: size(%image) картинок
//дописать процесс поиска по облостям
for #i 1 size(%image)   // цикл для поиска картинок (дописать)
    //присвоение значений по сетке поле 4*4 размером 400*400
    //код?
end_for
end_script

[cirus]

какой код нужен что бы связать поиск с присвоением значением массива?

код

Код

init_arr %image 2 4 8 16 32 64  // имена картинок
set $path "D:\_UOPilot\_2048\"    // путь к картинкам
init_arr %coord 403, 236 882, 713  // координаты для findimage


set #stepX (%coord [3] - %coord [1]) / 4   // шаг по X
set #stepY (%coord [4] - %coord [2]) / 4   // шаг по Y
set #z 0
for #i 1 size(%image)   // поиск картинок
    set #a findimage(%coord [1] %coord [2] %coord [3] %coord [4] ($path%image[#i].bmp) %arr 2 90 -1 3)
    if  #a > 0
        for #j 1 size(%arr)
            set #z #z + 1
            init_arr %temp (#z) %arr [#j 1] %arr [#j 2] %image[#i] // добавить в массив координаты и имя картинки
        end_for
    end_if
end_for

for #i 1 4   // заполнить массив 4*4 нулями
    init_arr %field (#i) 0 0 0 0
end_for

for #i 1 #z  // подсчёт позиции картинки на поле
    set #x (%temp [#i 1] - %coord [1]) / #stepX + 1
    set #y (%temp [#i 2] - %coord [2]) / #stepY + 1
    set %field [#y #x] %temp [#i 3]  // имя картинки в нужный элемент массива
end_for


log clear
log mode compact
set delimiter ' '
for #i 1 4            // вывод в лог
    log %field [#i]
end_for
set delimiter
end_script

Чтобы быстрее работало загрузить картинки в массив, сделать скрин и на нём искать картинки.

[NoName212]

Можно ли возвращать результат работы скрипта(числа) через вызов процедуры? Отправить скрипту координаты, он находит числа и возвращает строку

Код

set #x 30, 17
set #y 42, 113
call Number_meat #x #y 

if $Number_meat > 200
  ...
 if $Number_meat > 100
   ...
  if $Number_meat > 50
   ...
   if $Number_meat > 10
   ...
   end_if
  end_if
 end_if
end_if

как то так ... (IMG:style_emoticons/default/smile.gif)

один proc в котором скрипт, и 5-10 call'ов или сколько нужно... или только так можно: 1 proc - 1 call ?

___________

хотя можно по нескольким вкладкам скрипты разнеси останавливать их включать и т.д.