set %lockpick NWH

set %pandora CUD_HKF

set %maxweight #str * 35 / 10; #maxweight in EasyUO default is Str*3,7

;---------------------------------

finditem %pandora c_ , #backpackid

event Sysmessage In your backpack is #findcnt Pandora Box!

if #findcnt = 0

 halt

gosub unlock

gosub open

halt



sub unlock

set %unlockedboxes 0

event Sysmessage Unlocking...

wait 20

scanjournal

repeat

{

finditem %lockpick c_ , #backpackid

if #findcnt = 0

 gosub lockpicks

set #lobjectid #findid

event macro 17 0

target 4s

finditem %pandora c_ , #backpackid

 if #findcnt = 0

  {

  gosub pandora

  return

  }

set #ltargetid #findid

set #ltargetkind 1

event macro 22 0

deletejournal

gosub scan

}

until #false

return



sub scan

set %overTime #scnt + 10

repeat

{

for %i 1 3

 {

 scanjournal %i

 if you_fail in #journal || must_wait in #journal

  {

   wait 20

   return

  }

 if box_unlocked in #journal || is_already in #journal

  {

   set %done #true

   set %unlockedboxes %unlockedboxes + 1

   event Sysmessage %unlockedboxes box(es) unlocked!

   ignoreitem #ltargetid

   wait 20

   return

  }

 }

}

until #scnt > %overTime

return



sub open

set %openedboxes 0

ignoreitem reset

repeat

{

if #weight > %maxweight

 gosub weight

finditem %pandora c_ , #backpackid

 if #findcnt = 0

  {

   event Sysmessage There aren't any Pandora Box in you backpack!

   return

  }

set %pandoraCount #findcnt

set #lobjectID #findid

while #findcnt = %pandoraCount

{

 if #hits < 100

  {

   repeat

   {

   msg $.usebandage$

   event macro 23 0

   wait 10

   }

   until #hits = #maxhits

  }

 set #lobjectID #findid

 event macro 17 0

 wait 15

 if you_must_unlock in #sysmsg

 {

 set %done #false

 repeat

 {

 finditem %lockpick c_ , #backpackid

 if #findcnt = 0

 gosub lockpicks

 set #lobjectid #findid

 event macro 17 0

 target 4s

 finditem %pandora C_ , #backpackid

 set #ltargetid #findid

 set #ltargetkind 1

 event macro 22 0

 deletejournal

 gosub scan

 }

 until %done

 ignoreitem reset

 }

 finditem %pandora c_ , #backpackid

}

set %openedboxes %openedboxes + 1

event Sysmessage %openedboxes box(es) opened!

}

until #false

return



sub lockpicks

display ok Sysmessage Please buy more lockpicks and hit Play! $

+ Script is paused! $

pause

finditem %lockpick c_ , #backpackid

return



sub pandora

set #targcurs 0

event Sysmessage All of the Pandora Box have been unlocked!

wait 30

display yesno Do you want open Pandora Box automaticaly?

 if #dispres = yes

 {

 wait 20

 return

 }

 if #dispres = no

 {

 event Sysmessage Good luck opening boxes by Yourself #smc , )

 halt

 }

return



sub weight

display ok Your weight is full! $

+ Please make some free space in your backpack and hit Play! $

+ Script is paused! $

pause

return