Помогите плиз найти решение по созданию скрипта, не выходит привязать к окну Опции

[Mala-Anna]

Всем привет. попробую описать мою проблему.
я для одной игры (не имеет значения какой) прописала скрипты для 4 аккаунтов. каждый из них открывался в новом окне в фейсбуке в хроме . Для работы каждого из них требовалось сделать привязку к синей полоске меню самого фейса. При закрытии и новом открытии окна необходимо было перепривязать. окна практически никогда не закрывались. у меня был прописан скрипт-проводник и 4 закладки для каждого акка и скрипт-проводник их просто запускал. 1,5 года я так и делала и все работало замечательно. Но что то произошло с компом и он перестал тянуть 4 акка открытых все время. я решила прописать один большой общий скрипт который и будет открывать акки по очереди,выполнять все необходимые действия и закрывать их. но именно тут я и столкнулась с проблемой что такой скрипт не хочет привязываться к фейсу, потому что перезапустив страницу привязка слетает.соответственно окно открывается, скрипт бежит,но совершенно ничего не происходит. затем окно закрывается, открывается следующее и все так же.все работает кроме момента привязки к окну, без которой бесполезно все что я прописала, потому что сами действия на акке не производятся.... уже сутки сижу над этим... Возможно есть кто может подсказать решение? заранее спасибо!!

[FREEON]

для поиска картинки не нужно искать целое окно достаточно пару пикселей с закрашенным фоном
 bank.bmp ( 250 байт ) Кол-во скачиваний: 285

Но прежде всего стоит сделать проверку может активное окно не меняется. Для проверки скопируйте этот код в новую вкладку и подставьте свои данные в строки которые в комментарии отмечены //***.
1) Привязать свой запускаемый(рабочий, проверяемый) скрипт к рабочему окну.
2) Затем в код который вы скопировали в новую вкладку, нужно указать номер вкладки скрипта где вы запускаете свой скрипт.
3) Указать абсолютные координаты точки где появляется "новое" окно
4) Запускаем скрипт для проверки
5) Запускаем Ваш скрипт
6) ждем пока Ваш скрипт не завершит работу
7) Результат изменений PID окна будет хранится на диске C: под именем PID.txt

Код

set #scr 40           //***номер вкладки скрипта где вы запускаете свой скрипт
set $xy 268, 210 abs  //***абсолютные координаты точки где появляется "новое" окно
//--------------------------------------------
log clear
log mode compact
set linedelay 1         //Установить задержку между строками в 1 мс.
set #a workwindow.#scr  // сохранить в переменной #a хендл рабочего окна скрипта из вашей вкладки
log PID окна где делали привязку: #a
filedelete (C:\PID.txt) //обнулить файл
write (C:\PID.txt PID окна где делали привязку: #a \r\n)
get scripts %a          //получили данные о скриптах и их статусе
for #i 1 size(%a)       //ищем скрипт который мы указали, для определения его статуса
    log #i
    if  #scr = %a [#i 1]
        set #nomerSCR #i
        log наш скрипт: #nomerSCR
        break
    end_if
end_for
set $g %a [#nomerSCR 3]
log $g
set $off runing
while_not $g = $off //ждем пока не запустился проверяемый скрипт
    get scripts %a  //сверка статуса скрипта в текущий момент времени
    set $g %a [#nomerSCR 3]
    wait 100
end_while
while $g = $off     //производить скан PID до тех пор пока он запущен
    get scripts %a  //сверка статуса скрипта в текущий момент времени
    set $g %a [#nomerSCR 3]
    log $g
    get mouse_pos #x #y abs // получить координаты курсора перед смещением
    move $xy                // сместить курсор на наше окно
    wait 10
    set #b WindowFromCursor //записать в переменную хендл окна под курсором
    move #x #y abs          //вернуть курсор обратно в точку до смещения
    if  #a = #b             //если пид изменился запишем это изменение

    else
        log Pid окна изменился на: #b
        write (C:\PID.txt Pid окна изменился на: #b \r\n)
    end_if
    wait 1s
end_while
end_script