[ITEMDEF i_GM_tele_sphere]
DEFNAME=i_GM_tele_sphere
ID=0e2d
NAME=
WEIGHT=0

ON=@Click
MESSAGE=Сфера малого портала
return 1

ON=@Create
COLOR=055a
ATTR=attr_newbie|attr_move_never|attr_static

ON=@DCLICK
IF (<SRC.ACCOUNT.PLEVEL> > 1)
   TARGET
ELSE
   SRC.STONE
    SRC.SYSMESSAGE @0487 Откуда у Вас это?
   SRC.FindLayer(2).UnEquip
ENDIF
RETURN 1

ON=@TARGON_CHAR
IF (<EVAL <SRC.ACCOUNT.PLEVEL>> < <EVAL <SRC.TARG.ACCOUNT.PLEVEL>>) 
   RETURN 1
ENDIF
LINK=<SRC.TARG.UID>
TARGETG
RETURN 1

ON=@TARGON_ITEM
IF (<LINK>==04fffffff)
   DCLICK
ENDIF
LINK.GO <SRC.TARGP>
SRC.FIX
LINK=04fffffff
RETURN 1

ON=@TARGON_GROUND
IF (<LINK>==04fffffff)
   DCLICK
ENDIF
LINK.GO <SRC.TARGP>
SRC.FIX
LINK=04fffffff
RETURN 1

[ITEMDEF i_GM_resurrect_sphere]
DEFNAME=i_GM_resurrect_sphere
NAME=Game Master resurrect sphere
ID=0e2d

ON=@Click
MESSAGE=Сфера новой жизни
return 1

ON=@Create
COLOR=0898
ATTR=attr_newbie|attr_move_never|attr_static

ON=@DCLICK
IF (<SRC.ACCOUNT.PLEVEL> > 2)
   TARGET
   RETURN 1
ELSE
   SRC.STONE
    SRC.SYSMESSAGE @0487 Откуда у Вас это?
   SRC.FindLayer(2).UnEquip
   Return 1
EndIf

ON=@TARGON_ITEM
RETURN 1

ON=@TARGON_CHAR
IF (<SRC.TARG.HITS> > 0)
   IF (<SRC.TARG.STAM>!=<SRC.TARG.maxstam>)
      SRC.TARG.STAM=<SRC.TARG.maxstam>
      SRC.SYSMESSAGE @0487 Установлена максимальная стамина.
   ENDIF
   IF (<SRC.TARG.MANA>!=<SRC.TARG.maxmana>)
      SRC.TARG.MANA=<SRC.TARG.maxmana>
      SRC.SYSMESSAGE @0487 Установлена максимальна мана.
   ENDIF
   IF (<SRC.TARG.HITS>!=<SRC.TARG.maxhits>)
      SRC.TARG.HITS=<SRC.TARG.maxhits>
      SRC.SYSMESSAGE @0487 Установлено максимальное здоровье.
   ELSE
      SRC.SYSMESSAGE @0487 Существо еще живое.
   ENDIF
ELSE
   SRC.TARG.RESURRECT
   SRC.TARG.HITS=<SRC.TARG.STR>
   SRC.SYSMESSAGE @0487 Вы воскресили <SRC.TARG.NAME>!
ENDIF
RETURN 1

[ITEMDEF i_GM_stone_sphere]
DEFNAME=i_GM_stone_sphere
NAME=Game Master stone sphere
ID=0e2d

ON=@Click
MESSAGE=Сфера неподвижности
return 1

ON=@Create
COLOR=1154
ATTR=attr_newbie|attr_move_never|attr_static
MORE2=0

ON=@DCLICK
IF (<SRC.ACCOUNT.PLEVEL> > 1)
   TARGET
   RETURN 1
ELSE
   SRC.STONE
    SRC.SYSMESSAGE @0487 Откуда у Вас это?
   SRC.FindLayer(2).UnEquip
   RETURN 1
ENDIF

ON=@TARGON_ITEM
RETURN 1

ON=@TARGON_CHAR
IF (<EVAL <SRC.ACCOUNT.PLEVEL>> < <EVAL <SRC.TARG.ACCOUNT.PLEVEL>>)
    SRC.SYSMESSAGE @0487 Откуда у Вас это?
   RETURN 1
ENDIF
IF (<EVAL <SRC.TARG.FLAGS>&040000>)
   SRC.SYSMESSAGE You unparalyzed <SRC.TARG.NAME>
   SRC.TARG.TAG.GMSTONE=
   SRC.TARG.STONE
   RETURN 1
ELSE
   SRC.SYSMESSAGE You paralyzed <SRC.TARG.NAME>
   SRC.TARG.TAG.GMSTONE=1
   SRC.TARG.STONE
   RETURN 1
ENDIF