[ITEMDEF i_ale_redone]
//Created by Solitary Boy87 ||Solitary_Boy87@hotmail.com||
NAME=full bottle of ale
ID=i_bottle_ale
TYPE=T_BOOZE
VALUE={8 12}
WEIGHT=1
ON=@Create
MORE2=03

ON=@DCLICK
TARGET What do you want to use this on?
Return 1

ON=@TARGON_CHAR
IF <SRC.TARG.SERIAL>==<SRC.SERIAL>
MORE2=<MORE2>+-1
IF <MORE2>=02
NAME=a half full bottle of ale
ENDIF
IF <MORE2>=01
NAME=an almost empty bottle of ale
ENDIF
IF <MORE2>=00
REMOVE
ENDIF
IF <SRC.FINDID.i_alcohol_drunken>
SRC.ANIM 33
SRC.SOUND 49
SRC.FINDID.i_alcohol_drunken.MORE2=<SRC.FINDID.i_alcohol_drunken.MORE2>+2
Return 1
ELSE
SRC.ANIM 33
SRC.SOUND 49
SRC.NEWITEM=i_alcohol_drunken
SRC.ACT.EQUIP
SRC.ACT.TIMER 10
SRC.NEWITEM=i_alcohol_mana_penalty
SRC.ACT.EQUIP
SRC.ACT.TIMER 3
Return 1
ENDIF
ELSE
Return 1
ENDIF

CATEGORY=Equipment |Solitary_Boy87|
SUBSECTION=Alcohol |Solitary_Boy87|
DESCRIPTION=Ale

[ITEMDEF i_alcohol_drunken]
//Created by Solitary Boy87 ||Solitary_Boy87@hotmail.com||
NAME=Drunken Memory
ID=i_memory
TYPE=t_eq_script
LAYER=30

ON=@Equip
TIMER=10
MORE2=5
RETURN 1

ON=@Timer
IF <MORE2>=0
CONT.MESSAGE=You feel sober.
CONT.FINDID.i_alcohol_mana_penalty.REMOVE
REMOVE
Return 1
ELSE
CONT.BOW
CONT.SAY=*Hic*
MORE2=<MORE2>+-1
TIMER=10
Return 1
ENDIF

CATEGORY=Equipment |Solitary_Boy87|
SUBSECTION=Alcohol |Solitary_Boy87|
DESCRIPTION=Drunken |Memory|

[ITEMDEF i_alcohol_mana_penalty]
NAME=Drunken Memory [mana]
ID=i_memory
TYPE=t_eq_script
LAYER=30

ON=@Equip
TIMER=3
RETURN 1

ON=@TIMER
IF <CONT.MANA> == 1
CONT.MANA=<CONT.MANA>+-1
TIMER=3
ELSEIF <CONT.MANA> >= 2
CONT.MANA=<CONT.MANA>+-2
TIMER=3
ELSEIF <CONT.MANA>==0
TIMER=3
ENDIF

CATEGORY=Equipment |Solitary_Boy87|
SUBSECTION=Alcohol |Solitary_Boy87|
DESCRIPTION=Mana Penalty |Memory|

[ITEMDEF i_remedy]
//Created by Solitary Boy87 ||Solitary_Boy87@hotmail.com||
NAME=Jaana's Hangover Remedy
ID=0e2b

ON=@CREATE
COLOR=02d
MORE2=0100

ON=@CLICK
MESSAGE=<NAME>
Return 1

ON=@DCLICK
TARGET Who shall partake of the remedy?
Return 1

ON=@TARGON_CHAR
IF <SRC.TARG.SERIAL>==<SRC.SERIAL>
SRC.ANIM 33
SRC.SOUND 49
SRC.SYSMESSAGE=An awful taste fills your mouth.
SRC.FINDID.i_alcohol_mana_penalty.REMOVE
SRC.FINDID.i_alcohol_drunken.REMOVE
MORE2=<MORE2>+-1
Return 1
ELSE
Return 1
ENDIF

CATEGORY=Equipment |Solitary_Boy87|
SUBSECTION=Rares |Solitary_Boy87|
Description=Hangover Remedy

[EOF]